#include <Wire.h>  // 載入I2C程式庫
#include <LiquidCrystal_I2C.h> // 載入I2C_LCD模組程式庫
LiquidCrystal_I2C I2C_LCD(0x27,16,2);//設定LCD位址及行列數
#include <LedControl.h> // 載入SPI_MAX7219_LED矩陣控制程式庫 
LedControl LED_Matrix=LedControl(51,52,53,2); 
//LedControl(DIN[MOSI],CLK[SCK],CS[SS],LED_模組數)，DIN為LED模組腳位名稱，[MOSI]為SPI腳位名稱
int BZ=3; //蜂鳴器接腳
int Time=150; //預設每個音0.15s
String Song="1234567 CDEFGAB cdefgab"; //記錄歌曲之字串
int PitchM[]={262,294,330,349,392,440,494};//中音1(Do),2(Re),3(Mi),4(Fa),5(So),6(La),7(Ti)
int PitchL[]={131,147,165,175,196,220,247};//c(Do),d(Re),e(Mi),f(Fa),g(So),低音a(La),b(Ti)
int PitchH[]={523,587,659,698,784,880,988};//C(Do),D(Re),E(Mi),F(Fa),G(So),高音A(La),B(Ti)
const uint64_t P_LED0[7][2]={ //8*8_LED矩陣顯示音名
{0x00FE828244380000,0x007C8282827C0000},//DO
{0x00FE909894620000,0x00FE929292820000},//RE
{0x00FE403040FE0000,0x000082FE82000000},//MI
{0x00FE909090800000,0x007E8888887E0000},//FA
{0x00629292928C0000,0x007C8282827C0000},//SO
{0x00FE020202020000,0x007E8888887E0000},//LA
{0x008080FE80800000,0x000082FE82000000}};//TI 
void PlaySong(){//播放歌曲副程式
  Serial.print("歌曲音階=");
  Serial.println(Song);//印出歌曲Song字串，換行
  I2C_LCD.setCursor(0,1);  //設定游標為第0行，第1列(左下)
  for(int i=0;i<Song.length();i++){ //使i=0~歌曲字串長-1
    if(i>15)  //顯示超過16行
      I2C_LCD.autoscroll(); //LCD自動向左捲動
    char ch=Song[i];  //讀出音階代號  
    I2C_LCD.print(ch);  //LCD印出正要播之音階
    if(ch>='1' && ch<='7'){ //若為1~7 
      ch=ch-'1';      //轉成音階陣列號0~6
      tone(BZ,PitchM[ch]);  //播放中音
      DisplayP(ch);} //在8*8_LED矩陣顯示音名
    else if(ch>='A' && ch <='G'){//若為A~G
      if(ch>='C') ch=ch-'C';     //C~G轉成音階陣列號0~4
      else ch=ch-'A'+5;          //A~B轉成音階陣列號5~6
      tone(BZ,PitchH[ch]);  //播放高音
      DisplayP(ch); }        //在8*8_LED矩陣顯示音名
    else if(ch>='a' && ch<='g'){//若為a~g
      if(ch>='c') ch=ch-'c';     //c~g轉成音階陣列號0~4
      else ch=ch-'a'+5;          //a~b轉成音階陣列號5~6
      tone(BZ,PitchL[ch]);  //播放低音
      DisplayP(ch); }        //在8*8_LED矩陣顯示音名
    delay(Time); //蜂鳴器發音時間
    noTone(BZ);} //關聲音
  I2C_LCD.noAutoscroll(); I2C_LCD.clear();}//停止自動捲動，清除顯示器  
void DisplayP(char ch){         //在8*8_LED矩陣顯示音名
  for (int i = 0; i<8; i++) { 
    LED_Matrix.setRow(0,i,P_LED0[ch][0]>>(8*i));    //逐列顯示音名英文字母前
    LED_Matrix.setRow(1,i,P_LED0[ch][1]>>(8*i));}}  //逐列顯示音名英文字母後
void LEDOFF(int off){         // LED陣列是否關
  for(int i=0;i<2;i++)  {
    LED_Matrix.shutdown(i,off);     // off=0不關(即打開)，off=1關
    LED_Matrix.clearDisplay(i); } } // 清LED陣列
void setup() {  //初始設定
  LEDOFF(0);                          // LED陣列不關(即打開)
  for(int i=0;i<8;i++)  {
    LED_Matrix.setRow(0, i, 0xFF);    // LED陣列0逐列亮
    LED_Matrix.setIntensity(0,2*i);   // LED陣列0亮度為2i 
    LED_Matrix.setColumn(1, i, 0xFF); // LED陣列1逐行亮
    LED_Matrix.setIntensity(1,2*i);   // LED陣列1亮度為2i 
    delay(500);
  }
  Serial.begin(9600); //開啟串列埠，速度為9600bps
  I2C_LCD.begin(16,2);    //設定為16行，2列(行編號0-15，列編號0-1)
  I2C_LCD.backlight();    //打開背光
  I2C_LCD.print("Tone Time=200ms");
  pinMode(BZ, OUTPUT);          //蜂鳴器接腳設定為輸出
  PlaySong();
}//setup()初始設定，結束
void loop() {//重覆執行無窮迴圈
  if(Serial.available()){ //若序列埠有輸入
    LEDOFF(0);              // LED陣列不關(即打開)
    I2C_LCD.backlight();    //打開背光
    char ch=Serial.read();    //讀入序列埠資料
    if(ch == '+')  {if(Time>50) {Time-=50;Serial.println("加速!");}}//按[+]。加速
    else if(ch == '-')  {Time+=50;Serial.println("減速!");}//按[-]，減速
    else if(ch == '*')  PlaySong();//按[*]，再播歌
    else if(ch == '/')  {Song="";Serial.println("刪歌!");}//按[/]，刪歌
    else {                      //若非設定字元，即為有新加入音
      Song=Song+ch;             //加在原歌後面
      while(Serial.available()){ //若序列埠仍有資料
        ch=Serial.read();       //讀入序列埠資料
        if(ch !=0x0A)           //不是換行符號
          Song=Song+ch;          //加在原歌後面
      }
      PlaySong();              //讀完播放歌曲
    }
    delay(1000);                 //延遲1秒
  }              
    I2C_LCD.home();             //回左上
    I2C_LCD.print("Tone Time=");I2C_LCD.print(Time);I2C_LCD.print("ms ");//印每音時間
    I2C_LCD.noBacklight();      //關閉背光
    LEDOFF(1);                  // LED陣列關
}//loop()重覆執行無窮迴圈，結束