#include <Arduino.h>
#include <WiFi.h>
#include <Wire.h>
#include <PubSubClient.h>
#include <Adafruit_Sensor.h>
#include <DHT.h>

// Define the pin and type of the DHT sensor
#define DHTPIN 5      
#define DHTTYPE DHT22 

// Initialize DHT sensor
DHT dht(DHTPIN, DHTTYPE);

// WiFi and MQTT client objects
WiFiClient wifiClient;
PubSubClient mqttClient(wifiClient);

// WiFi credentials
const char* ssid = "Wokwi-GUEST";
const char* pass = "";

// MQTT broker details
const char* mqttServer = "mqtt-dashboard.com";
int mqttPort = 1883;

// Timing variables for periodic data publishing
int period = 6000;
unsigned long time_now = 0;

// MQTT callback function
void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  String data = "";
  for (unsigned int i = 0; i < length; i++) {
    Serial.print((char)message[i]);
    data += (char)message[i];
  }
  Serial.println();
}

// Set up MQTT connection
void setupMQTT() {
  mqttClient.setServer(mqttServer, mqttPort);
  mqttClient.setCallback(callback);
}

// Reconnect to MQTT broker if disconnected
void reconnect() {
  Serial.println("Connecting to MQTT Broker...");
  while (!mqttClient.connected()) {
    Serial.println("Reconnecting to MQTT Broker...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);

    if (mqttClient.connect(clientId.c_str())) {
      Serial.println("Connected.");
      // Subscribe to a topic
      mqttClient.subscribe("b15-esp32/message");
    }
  }
}

// Setup function to initialize serial communication, WiFi, DHT sensor, and MQTT
void setup() {
  Serial.begin(115200);
  pinMode(15, OUTPUT); // Example pin, not used in the current setup
  dht.begin();
  
  // Connect to Wi-Fi
  WiFi.begin(ssid, pass);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();
  Serial.println("Connected to Wi-Fi");

  // Initialize MQTT
  setupMQTT();
}

// Main loop to handle MQTT connection and sensor data publishing
void loop() {
  if (!mqttClient.connected()) {
    reconnect();
  }
  mqttClient.loop();

  // Publish data periodically
  if (millis() - time_now >= period) {
    time_now = millis();

    // Read temperature from DHT22 sensor
    float temperature = dht.readTemperature();
    char tempString[8];
    dtostrf(temperature, 1, 2, tempString);
    Serial.print("Temperature: ");
    Serial.println(tempString);
    mqttClient.publish("b15-esp32/temperature", tempString);

    // Read humidity from DHT22 sensor
    float humidity = dht.readHumidity();
    char humString[8];
    dtostrf(humidity, 1, 2, humString);
    Serial.print("Humidity: ");
    Serial.println(humString);
    mqttClient.publish("b15-esp32/humidity", humString);

    // Publish a combined message
    String combinedData = "Temperature: " + String(temperature) + ", Humidity: " + String(humidity);
    mqttClient.publish("b15-esp32/sub", combinedData.c_str());
  }
}