//https://www.arduino.cc/reference/en/libraries/wifi/
#include <WiFi.h>
/***************************************************************
              Definiciones
***************************************************************/
#define BUSQUEDA_RETARDO 5000
/***************************************************************
              Funcion de configuración Setup
***************************************************************/
void setup() {
  Serial.begin(115200);
  /***************************************************************
              Configuración WiFi
  ***************************************************************/
  WiFi.mode(WIFI_STA);
  WiFi.enableSTA(true);
  WiFi.disconnect();
  delay(100);
  Serial.println("Reset Ok");
}
/***************************************************************
              Ciclo principal Loop
***************************************************************/
void loop() {
  buscarRedesWiFi();
}
/***************************************************************
              Funciones del Programa
***************************************************************/
void buscarRedesWiFi() {
  Serial.println("Iniciar Busqueda de redes WiFi");
  int numero_redes_WiFi = WiFi.scanNetworks();
  Serial.println("Busqueda terminada");
  if (numero_redes_WiFi == 0) {
    Serial.println("No se encontraron redes");
  } else {
    Serial.print(numero_redes_WiFi);
    Serial.println(" Redes encontradas");
    Serial.println("Nr | SSID                             | RSSI | CH | Encriptación");
    for (int i = 0; i < numero_redes_WiFi; ++i) {
      Serial.printf("%2d", i + 1);
      Serial.print(" | ");
      Serial.printf("%-32.32s", WiFi.SSID(i).c_str());
      Serial.print(" | ");
      Serial.printf("%4d", WiFi.RSSI(i));
      Serial.print(" | ");
      Serial.printf("%2d", WiFi.channel(i));
      Serial.print(" | ");
      switch (WiFi.encryptionType(i)) {
        case WIFI_AUTH_OPEN:
          Serial.print("Abierta");
          break;
        case WIFI_AUTH_WEP:
          Serial.print("WEP");
          break;
        case WIFI_AUTH_WPA_PSK:
          Serial.print("WPA");
          break;
        case WIFI_AUTH_WPA2_PSK:
          Serial.print("WPA2");
          break;
        case WIFI_AUTH_WPA_WPA2_PSK:
          Serial.print("WPA+WPA2");
          break;
        case WIFI_AUTH_WPA2_ENTERPRISE:
          Serial.print("WPA2-EAP");
          break;
        case WIFI_AUTH_WPA3_PSK:
          Serial.print("WPA3");
          break;
        case WIFI_AUTH_WPA2_WPA3_PSK:
          Serial.print("WPA2+WPA3");
          break;
        case WIFI_AUTH_WAPI_PSK:
          Serial.print("WAPI");
          break;
        default:
          Serial.print("Desconocida");
      }
      Serial.println();
      delay(10);
    }
  }
  Serial.println("");
  WiFi.scanDelete();
  delay(BUSQUEDA_RETARDO);
}