#include <WiFi.h>
#include <HTTPClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include "DHT.h"

#define DHTPIN 4
#define DHTTYPE DHT22
#define SOIL_MOISTURE_PIN 34
#define PH_PIN 35

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* server = "http://api.thingspeak.com/update";
const char* apiKey = "WFIBCHWM40UHAZFV";

DHT dht(DHTPIN, DHTTYPE);
LiquidCrystal_I2C LCD(0x27, 16, 2);

// Function to map analog readings to pH values
float mapToPH(int sensorValue) {
  // Map the analog sensor value (0-4095) to the pH range (1-14)
  return 1 + (sensorValue / 4095.0) * 13.0;
}

void spinner() {
  static int8_t counter = 0;
  const char* glyphs = "\xa1\xa5\xdb";
  LCD.setCursor(15, 1);
  LCD.print(glyphs[counter++]);
  if (counter == strlen(glyphs)) {
    counter = 0;
  }
}

void setup() {
  Serial.begin(115200);
  
  LCD.init();
  LCD.backlight();
  LCD.setCursor(0, 0);
  LCD.print("Connecting to ");
  LCD.setCursor(0, 1);
  LCD.print("WiFi ");

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(250);
    spinner();
  }
  Serial.println("WiFi connected");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  // Initialize DHT sensor
  dht.begin();

  LCD.clear();
  LCD.setCursor(0, 0);
  LCD.println("Online");
  LCD.setCursor(0, 1);
  LCD.println("Updating time...");

  configTime(0, 0, "pool.ntp.org");
}

void loop() {
  // Ensure WiFi is connected
  if (WiFi.status() != WL_CONNECTED) {
    Serial.println("Reconnecting to WiFi...");
    WiFi.begin(ssid, password);
    while (WiFi.status() != WL_CONNECTED) {
      delay(1000);
      Serial.print(".");
    }
    Serial.println(" Connected!");
  }

  // Read sensor data
  float humidity = dht.readHumidity();
  float temperature = dht.readTemperature();
  int soilMoisture = analogRead(SOIL_MOISTURE_PIN);
  int phSensorValue = analogRead(PH_PIN);

  // Check if any readings failed and exit early (to try again in the next loop)
  if (isnan(humidity) || isnan(temperature)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  // Map the pH sensor analog reading to pH value
  float pHValue = mapToPH(phSensorValue);

  // Print sensor values to Serial
  Serial.print("Humidity: ");
  Serial.print(humidity);
  Serial.print(" %\t");
  Serial.print("Temperature: ");
  Serial.print(temperature);
  Serial.print(" *C\t");
  Serial.print("Soil Moisture: ");
  Serial.print(soilMoisture);
  Serial.print("\t");
  Serial.print("pH Value: ");
  Serial.println(pHValue);

  if (WiFi.status() == WL_CONNECTED) {
    HTTPClient http;
    String url = String(server) + "?api_key=" + apiKey + "&field1=" + String(humidity) + "&field2=" + String(temperature) + "&field3=" + String(soilMoisture) + "&field4=" + String(pHValue);
    
    Serial.print("Request URL: ");
    Serial.println(url); // Print URL for debugging
    
    http.begin(url);
    int httpResponseCode = http.GET();
    
    if (httpResponseCode > 0) {
      Serial.print("HTTP Response code: ");
      Serial.println(httpResponseCode);
      Serial.println("Data sent to ThingSpeak successfully.");
      // Print the last sent data
      Serial.print("Last sent data - Humidity: ");
      Serial.print(humidity);
      Serial.print(" %, Temperature: ");
      Serial.print(temperature);
      Serial.print(" *C, Soil Moisture: ");
      Serial.print(soilMoisture);
      Serial.print(", pH Value: ");
      Serial.println(pHValue);
    } else {
      Serial.print("Error code: ");
      Serial.println(httpResponseCode);
      Serial.println(http.errorToString(httpResponseCode).c_str());
    }
    http.end();
  } else {
    Serial.println("WiFi Disconnected");
  }
  
  // Delay for 60 seconds before sending the next data
  delay(60000); // Send data every 60 seconds
}