#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <Wire.h>
#include <WiFi.h>
#include <PubSubClient.h>

// MPU6050
Adafruit_MPU6050 mpu;

// WiFi
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// MQTT
const char* mqtt_server = "io.adafruit.com";
const char* mqtt_username = "japs1989";
const char* mqtt_password = "aio_vGTT60mOTFAVGqwX5S1wjVJt2Uyw";

// MQTT Topics
const char* TOPIC_ACCEL_X = "japs1989/f/Accel_X";
const char* TOPIC_ACCEL_Y = "japs1989/f/Accel_Y";
const char* TOPIC_ACCEL_Z = "japs1989/f/Accel_Z";
const char* TOPIC_TEMP = "japs1989/f/Temp";

WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
  delay(10);
  Serial.print("Conectando a ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi conectado");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  while (!client.connected()) {
    Serial.println("Intentando conexión MQTT ...");
    String clientId = "esp32-mpu6050-clientId-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str(), mqtt_username, mqtt_password)) {
      Serial.println("Conectado");
    } else {
      Serial.print("Conexión fallida: ");
      Serial.print(client.state());
      Serial.println(" Intente en 5 segundos");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);

  if (!mpu.begin()) {
    Serial.println("No se pudo encontrar un sensor MPU6050, revise las conexiones");
    while (1) {
      delay(10);
    }
  }
  
  setup_wifi();
  client.setServer(mqtt_server, 1883);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  sensors_event_t acc, gyro, temp;
  mpu.getEvent(&acc, &gyro, &temp);

  client.publish(TOPIC_ACCEL_X, String(acc.acceleration.x, 2).c_str());
  client.publish(TOPIC_ACCEL_Y, String(acc.acceleration.y, 2).c_str());
  client.publish(TOPIC_ACCEL_Z, String(acc.acceleration.z, 2).c_str());
  client.publish(TOPIC_TEMP, String(temp.temperature, 2).c_str());

  delay(10000); // Publicar datos cada 10 segundos
}