#include <Wire.h>
#include <WiFi.h>
#include <DHT.h>
#include <PubSubClient.h>
#include <Arduino.h>
#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>

#define DHT_PIN 12
#define PULSE_PIN 35

#define MQTT_SERVER "broker.emqx.io"
#define MQTT_PORT 1883

const char *ssid = "Wokwi-GUEST";
const char *password = "";

#define MQTT_TOPIC_HR "/heartRate"
#define MQTT_TOPIC_TEMP "/tempValue"
#define MQTT_TOPIC_HUM "/humValue"
#define MQTT_TOPIC_ACCEL "/accelData"
#define MQTT_TOPIC_GYRO "/gyroData"

WiFiClient espClient;
PubSubClient client(espClient);

DHT dht(DHT_PIN, DHT22);
Adafruit_MPU6050 mpu;

void setup() {
  Wire.begin(23, 22); // SDA on GPIO 23, SCL on GPIO 22
  Serial.begin(115200);
  Serial.println("Hello, ESP32!");

  connectToWiFi();

  client.setServer(MQTT_SERVER, MQTT_PORT);

  dht.begin();

  // Initialize MPU6050
  if (!mpu.begin()) {
    Serial.println("MPU6050 not connected!");
    while (1);
  }
  Serial.println("MPU6050 connected!");
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }

  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();

  // Read pulseValue from PULSE_PIN
  int16_t pulseValue = analogRead(PULSE_PIN);

  // Convert pulseValue to voltage
  float voltage = pulseValue * (3.3 / 4095.0);

  // Calculate heartRate from voltage (simplified example, adjust as needed)
  int heartRate = (voltage / 3.3) * 675;

  // Print HeartRate
  Serial.print("Heart Rate: ");
  Serial.print(heartRate);
  Serial.print(" Temp: ");
  Serial.print(temperature);
  Serial.print(" Humidity: ");
  Serial.println(humidity);

  // Read MPU6050 data
  sensors_event_t accel, gyro, temp;
  mpu.getEvent(&accel, &gyro, &temp);

  Serial.print("Accel: ");
  Serial.print(accel.acceleration.x); Serial.print(", ");
  Serial.print(accel.acceleration.y); Serial.print(", ");
  Serial.println(accel.acceleration.z);

  Serial.print("Gyro: ");
  Serial.print(gyro.gyro.x); Serial.print(", ");
  Serial.print(gyro.gyro.y); Serial.print(", ");
  Serial.println(gyro.gyro.z);

  client.publish(MQTT_TOPIC_HR, String(heartRate).c_str());
  client.publish(MQTT_TOPIC_TEMP, String(temperature).c_str());
  client.publish(MQTT_TOPIC_HUM, String(humidity).c_str());

  String accelData = String(accel.acceleration.x) + "," + String(accel.acceleration.y) + "," + String(accel.acceleration.z);
  String gyroData = String(gyro.gyro.x) + "," + String(gyro.gyro.y) + "," + String(gyro.gyro.z);

  client.publish(MQTT_TOPIC_ACCEL, accelData.c_str());
  client.publish(MQTT_TOPIC_GYRO, gyroData.c_str());

  delay(1000); // Increased delay to 1 second for more stability
}

void connectToWiFi() {
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi...");
  }
  Serial.println("Connected to WiFi");
}

void reconnect() {
  while (!client.connected()) {
    if (client.connect("esp32_neopixel_controller")) {
      Serial.println("Connected to MQTT");
      // subscribeToCommands();
    } else {
      Serial.print("Failed, rc=");
      Serial.print(client.state());
      Serial.println(" Retrying in 5 seconds...");
      delay(5000);
    }
  }
}