#include <WiFi.h> 
#include <HTTPClient.h>
#include <DHT.h>

const char* ssid = "Wokwi-GUEST"; 
const char* password = ""; 
const char* accessToken = "j1vjvgogxn38lfu7a2qu";
const char* server = "http://thingsboard.cloud/api/v1/vbkmr44b00vkbc4pvs22/telemetry";

#define DHTPIN 12 
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

HTTPClient http;

void setup() {
  Serial.begin(115200);
  dht.begin();

  WiFi.begin(ssid, password);
  unsigned long startAttemptTime = millis();

  while (WiFi.status() != WL_CONNECTED && millis() - startAttemptTime < 10000) {
    delay(500);
    Serial.println("Connecting to WiFi...");
  }

  if (WiFi.status() == WL_CONNECTED) {
    Serial.println("Connected to WiFi");
  } else {
    Serial.println("Failed to connect to WiFi");
  }

  http.begin(server);
  http.addHeader("Content-Type", "application/json");
}

void loop() {
  if (WiFi.status() != WL_CONNECTED) {
    // Reconnect WiFi
    WiFi.begin(ssid, password);
    unsigned long startAttemptTime = millis();

    while (WiFi.status() != WL_CONNECTED && millis() - startAttemptTime < 10000) {
      delay(500);
      Serial.println("Reconnecting to WiFi...");
    }

    if (WiFi.status() == WL_CONNECTED) {
      Serial.println("Reconnected to WiFi");
    } else {
      Serial.println("Failed to reconnect to WiFi");
      return;
    }
  }

  float temperature = dht.readTemperature();  
  float humidity = dht.readHumidity();

  if (isnan(temperature) || isnan(humidity)) { 
    Serial.println("Failed to read from DHT sensor!");
    delay(2000);
    return;
  }

  Serial.print("Temperature: ");
  Serial.print(temperature);
  Serial.print(" °C, Humidity: ");
  Serial.print(humidity);
  Serial.println(" %");

  String payload = "{\"temperature\": " + String(temperature, 2) + ", \"humidity\": " + String(humidity, 2) + "}"; 

  Serial.print("Sending data to: ");
  Serial.println(server);
  Serial.print("Payload: ");
  Serial.println(payload);

  int httpResponseCode = http.POST(payload);

  if (httpResponseCode > 0) { 
    String response = http.getString();
    Serial.println(httpResponseCode);
    Serial.println(response); 
  } else {
    Serial.print("Error on sending POST: ");
    Serial.println(httpResponseCode);
  }

  delay(1000);
}