#define BLYNK_TEMPLATE_ID "TMPL6UuuGLd95"
#define BLYNK_TEMPLATE_NAME "Smart Aquarium"
#define BLYNK_AUTH_TOKEN "ewan5qIKjDCb5ctS-ds8Hsmzd4_ujsQC"

#include <WiFi.h>
#include <PubSubClient.h>
#include <ESP32Servo.h>
#include <Adafruit_NeoPixel.h>
#include <BlynkSimpleEsp32.h>

char auth[] = BLYNK_AUTH_TOKEN;

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "free.mqtt.iyoti.id";    // BROKER
const char* mqtt_client_id = "mqtt_iyoti_1Dp8Ot7H1K";
const int mqtt_port = 8083;
const char* mqtt_topic_subscribe = "smart_aquarium_sister/commands";
const char* mqtt_topic_publish_light = "smart_aquarium_sister/light";
const char* mqtt_topic_publish_water = "smart_aquarium_sister/water";

WiFiClient espClient;
PubSubClient client(espClient);
Servo myservo;

const int trigPin = 18;
const int echoPin = 17;
const int ldrPin = 34;
const int servoPin = 4;
const int neoLength = 16;
const int neoDIN = 12;
const int SwitchPin = 22;

#define SwitchPin_v V1

BLYNK_CONNECTED() {
  Blynk.syncVirtual(SwitchPin_v);
}

Adafruit_NeoPixel strip(neoLength, neoDIN, NEO_GRB + NEO_KHZ800);

BLYNK_WRITE(SwitchPin_v) {
  int switchState = param.asInt();
  digitalWrite(SwitchPin, switchState);
  if (switchState == 1) {
    myservo.write(180); // Feed the fish
    Serial.println("Feeding the fish");
  } else {
    myservo.write(0); // Stop feeding
    Serial.println("Fish has been fed");
  }
}

// Connect to WiFi
void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("WiFi connected - IP address: ");
  Serial.println(WiFi.localIP());
}

// Handle incoming MQTT messages
void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
}

// Reconnect to MQTT if disconnected
void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect(mqtt_client_id)) {
      Serial.println("connected");
      client.subscribe(mqtt_topic_subscribe);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  setup_wifi();
  Blynk.begin(auth, ssid, password);
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
  myservo.attach(servoPin);
  strip.begin();
  strip.show();
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
  pinMode(SwitchPin, INPUT);
}

void loop() {
  Blynk.run();
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  
  // Ultrasonic sensor to check water level
  long duration, distance;
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);
  duration = pulseIn(echoPin, HIGH);
  distance = duration * 0.034 / 2;
  String distanceString = String(distance);
  client.publish(mqtt_topic_publish_water, distanceString.c_str());

  Serial.println("Checking water level...");
  Serial.print("Water level: ");
  Serial.print(distance);
  Serial.println(" cm");

  // LDR to check light intensity
  int ldrValue = analogRead(ldrPin);
  String ldrStringValue = String(ldrValue);
  client.publish(mqtt_topic_publish_light, ldrStringValue.c_str());
  Serial.print("LDR Value: ");
  Serial.println(ldrValue);
  int neoBrightness = map(ldrValue, 0, 1023, 0, 255);

  Serial.println("Adjusting NeoPixel brightness");
  for(int i = 0; i < strip.numPixels(); i++) {
    strip.setPixelColor(i, strip.Color(neoBrightness, neoBrightness, neoBrightness));
  }
  strip.show();
  
  delay(1000);
}