#include <WiFi.h>
#include <PubSubClient.h>
#include <DHTesp.h>
#include <LiquidCrystal_I2C.h>
#include <ArduinoJson.h>

LiquidCrystal_I2C lcd(0x27, 16, 2);

int led = 13;  // led is connected to esp32 D13
int pirdata = 14;  // pir D is connected to D14
int pirstate = LOW;  // assuming no motion
int value = 0;  // to read pin status

const int DHT_PIN = 15;
DHTesp dht;

const char* ssid = "Wokwi-GUEST";  // wifi ssid
const char* password = "";
const char* mqtt_server = "broker.hivemq.com";  // change to hivemq broker
const char* MQTT_Topic = "baocaodiot_dht22";

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  String message;
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
    message += (char)payload[i];
  }
  Serial.println();

  // Parse JSON message
  StaticJsonDocument<200> doc;
  DeserializationError error = deserializeJson(doc, message);
  if (!error) {
    const char* command = doc["command"];
    if (strcmp(command, "on") == 0) {
      digitalWrite(led, HIGH);
    } else if (strcmp(command, "off") == 0) {
      digitalWrite(led, LOW);
    }
  } else {
    Serial.println("Failed to parse JSON message");
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("Connected");
      client.subscribe(MQTT_Topic);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  pinMode(led, OUTPUT);
  pinMode(pirdata, INPUT);
  lcd.init();
  lcd.backlight();
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  dht.setup(DHT_PIN, DHTesp::DHT22);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  value = digitalRead(pirdata);
  if (value == HIGH) {
    digitalWrite(led, HIGH);
    if (pirstate == LOW) {
      Serial.println("Motion detected!");
      pirstate = HIGH;
    }
  } else {
    digitalWrite(led, LOW);
    if (pirstate == HIGH) {
      Serial.println("Motion ended!");
      pirstate = LOW;
    }
  }

  unsigned long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;
    TempAndHumidity data = dht.getTempAndHumidity();
    lcd.clear();
    String temp = String(data.temperature, 2);
    String hum = String(data.humidity, 1);

    // Create JSON message
    StaticJsonDocument<200> doc;
    doc["temperature"] = temp;
    doc["humidity"] = hum;
    doc["motion"] = (pirstate == HIGH) ? "detected" : "none";

    char jsonString[200];
    serializeJson(doc, jsonString);

    client.publish(MQTT_Topic, jsonString);

    Serial.print("Temperature: ");
    Serial.println(temp);
    lcd.print("Temp: ");
    lcd.print(temp);
    Serial.print("Humidity: ");
    Serial.println(hum);
    lcd.setCursor(0, 1);
    lcd.print("Humidity: ");
    lcd.print(hum);
  }
}