#include <WiFi.h>
const char ssid[] = "Wokwi-GUEST";
const char password[] = "";
WiFiClient client;

#include<ThingSpeak.h>
const long CHANNEL = 2575218;
const char *WRITE_API = "SRD8Y56446G3H7MH";
#define pinTEMP 15                    // Pino do sensor de Temperatura

#define PULSE_PER_BEAT    1           // Número de pulsos por batimento cardíaco
#define INTERRUPT_PIN     5           // Pino de interrupção
#define SAMPLING_INTERVAL 15000        // Intervalo de amostragem em milissegundos

volatile uint16_t pulse;              // Variável que será incrementada na interrupção
uint16_t count;                       // Variável para armazenar o valor atual de pulse
float heartRate;                      // Frequência cardíaca calculada a partir de count

const float BETA = 3950;              // Variável do coeficiente BETA do termistor

unsigned long cont = 0;


portMUX_TYPE mux = portMUX_INITIALIZER_UNLOCKED;  // Mutex para garantir acesso seguro a pulse

long prevMillisThingsSpeak = 0;
int intervalThingSpeak = 15000;

void IRAM_ATTR HeartRateInterrupt() {
  portENTER_CRITICAL_ISR(&mux);  // Entra em uma seção crítica de interrupção
  pulse++;                       // Incrementa a variável pulse de maneira segura
  portEXIT_CRITICAL_ISR(&mux);   // Sai da seção crítica de interrupção
}


void setup() {

  Serial.begin(115200);
  Serial.println();
  Serial.println("Envia os dados do sensor para o ThingSpeak usando o ESP32");

  WiFi.mode(WIFI_STA);
  ThingSpeak.begin(client);

  analogReadResolution(10);      // Define o tamanho (em bits) dos valores lido em 10 bits (valores de 0 a 1023)
  pinMode(INTERRUPT_PIN, INPUT);
  pinMode(pinTEMP, OUTPUT);
  attachInterrupt(digitalPinToInterrupt(INTERRUPT_PIN), HeartRateInterrupt, RISING);  // Configura a interrupção no pino
}

void loop() {

  if(WiFi.status() != WL_CONNECTED) {
    Serial.print("Atencao para conectar o SSID: ");
    Serial.println(ssid);
    while (WiFi.status() != WL_CONNECTED) {
      WiFi.begin(ssid, password);
      Serial.print(".");
      delay(5000);
    }
    Serial.println("\nConectado");
  }
    HeartRateandTemperature();


}


void HeartRateandTemperature() {
  static unsigned long startTime;
  if (millis() - startTime < SAMPLING_INTERVAL) return;   // Intervalo de amostragem
  startTime = millis();

  portENTER_CRITICAL(&mux);   // Entra em uma seção crítica
  count = pulse;              // Salva o valor atual de pulse e zera pulse
  pulse = 0;
  portEXIT_CRITICAL(&mux);    // Sai da seção crítica

  // Ajuste na fórmula para mapear a faixa de 0 Hz a 220 Hz para a frequência cardíaca em BPM
  //heartRate = map(count, 0, 220, 0, 220);  // Mapeia a contagem para a faixa desejada
  heartRate = (60000.0f / SAMPLING_INTERVAL) * count / PULSE_PER_BEAT; 

  // Fórmula para cálculo da temperatura corporal em celsius
  int valorTemp = analogRead(pinTEMP);
  float tempCorp = 1 / (log(1 / (1023. / valorTemp - 1)) / BETA + 1.0 / 298.15) - 273.15;

  cont++;       // A cada impressão, incrementa um valor (para número de análise)

  Serial.println("Análise " + String(cont) + ":");
  Serial.println("Temperatura Corporal: " + String(tempCorp) + " ℃");
  Serial.println("Frequência Cardíaca: " + String(heartRate, 2) + " BPM");
  Serial.println("----");

  if (millis() - prevMillisThingsSpeak > intervalThingSpeak) {
    ThingSpeak.setField(1, tempCorp);
    ThingSpeak.setField(2, heartRate);

    int x = ThingSpeak.writeFields(CHANNEL, WRITE_API);
    if (x == 200) {
      Serial.println("Update realizado com sucesso");
    } else {
      Serial.println("Problema no canal - erro HTTP " + String(x));
    }

    prevMillisThingsSpeak = millis();
  }
}