//新增DHT函數庫，更改第6行腳位，更改第63行與第64行可以推播實際的溫度與溼度
#include <WiFi.h>
#include <PubSubClient.h> //請先安裝PubSubClient程式庫
// DHT 22  (AM2302), AM2321
#include "DHT.h"
#define DHTPIN 23     
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE); // DHT 定義為dht

// ------ 以下修改成你自己的WiFi帳號密碼 ------
char* ssid = "Wokwi-GUEST"; //請修改為您連線的網路名稱
char* password = ""; //請修改為您連線的網路密
// ------ 以下修改成你MQTT設定 ------
char* MQTTServer = "mqttgo.io";//免註冊MQTT伺服器
int MQTTPort = 1883;//MQTT Port 除非加密，否則不用更改port
char* MQTTUser = "";//不須帳密
char* MQTTPassword = "";//不須帳密

//推播主題1:推播訊息(記得改Topic)
char* MQTTPubTopic1 = "YourTopic/class/22311";
//推播主題2:推播數字(記得改Topic)
char* MQTTPubTopic2 = "YourTopic/class/32311";
//訂閱主題1:改變LED燈號(記得改Topic)
char* MQTTSubTopic1 = "YourTopic/class/12311";
long MQTTLastPublishTime;//此變數用來記錄推播時間
long MQTTPublishInterval = 10000;//每10秒推撥一次
//建立MQTT與聯網物件
WiFiClient WifiClient;
PubSubClient MQTTClient(WifiClient);

void setup() {
  Serial.begin(115200);
  pinMode(2, OUTPUT);//紅色LED燈
  //開始WiFi連線
  WifiConnecte();
  //開始MQTT連線
  MQTTConnecte();
//開始dht
  dht.begin();
}

void loop() {
//擷取DHT的溫度與溼度
  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();
  Serial.print(F("Humidity: "));
  Serial.print(humidity);
  Serial.print(F("%  Temperature: "));
  Serial.print(temperature);
  Serial.println(F("°C "));



  //如果WiFi連線中斷，則重啟WiFi連線
  if (WiFi.status() != WL_CONNECTED) { WifiConnecte(); }

  //如果MQTT連線中斷，則重啟MQTT連線
  if (!MQTTClient.connected()) {  MQTTConnecte(); }

  //如果距離上次傳輸已經超過10秒，則Publish溫溼度
  if ((millis() - MQTTLastPublishTime) >= MQTTPublishInterval ) {
//將溫度與溼度推播Publish
    String tempString = String(temperature);
    String humiString = String(humidity);
    MQTTClient.publish(MQTTPubTopic1, tempString.c_str());//將溫度推播到MQTTPubTopic1
    MQTTClient.publish(MQTTPubTopic2, humiString.c_str());//將溼度推播到MQTTPubTopic2


    Serial.println("訊息已推播到MQTT Broker");
    MQTTLastPublishTime = millis(); //更新最後傳輸時間
  }
  MQTTClient.loop();//更新訂閱狀態
  delay(50);
}

//開始WiFi連線
void WifiConnecte() {
  //開始WiFi連線
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("WiFi連線成功");
  Serial.print("IP Address:");
  Serial.println(WiFi.localIP());
}

//開始MQTT連線
void MQTTConnecte() {
  MQTTClient.setServer(MQTTServer, MQTTPort);
  //以下開始處理訂閱主題
  MQTTClient.setCallback(MQTTCallback); //收到訂閱資料時，要處理MQTTCALLBACK
  while (!MQTTClient.connected()) {
    //以亂數為ClietID
    String  MQTTClientid = "esp32-" + String(random(1000000, 9999999));//建立一個郵差，為了要不一樣，所以使用亂數
    if (MQTTClient.connect(MQTTClientid.c_str(), MQTTUser, MQTTPassword)) {
      //連結成功，顯示「已連線」。
      Serial.println("MQTT已連線");
      //訂閱SubTopic1主題
      MQTTClient.subscribe(MQTTSubTopic1);
    } else {
      //若連線不成功，則顯示錯誤訊息，並重新連線
      Serial.print("MQTT連線失敗,狀態碼=");
      Serial.println(MQTTClient.state());
      Serial.println("五秒後重新連線");
      delay(5000);
    }
  }
}

//接收到訂閱時
void MQTTCallback(char* topic, byte* payload, unsigned int length) {
  Serial.print(topic); Serial.print("訂閱通知:");
  String payloadString;//將接收的payload轉成字串
  //顯示訂閱內容
  for (int i = 0; i < length; i++) {
    payloadString = payloadString + (char)payload[i];
  }
  Serial.println(payloadString);
  //比對主題是否為訂閱主題1，若相同則執行動作的部分，需要注意payloadString內容的資料是否與app內的訊息相同。
  if (strcmp(topic, MQTTSubTopic1) == 0) {
    Serial.println("改變燈號：" + payloadString);
    if (payloadString == "on") {
      digitalWrite(2, HIGH);
    }
    if (payloadString == "off") {
      digitalWrite(2, LOW);
    }
  }
}