#include <WiFi.h>
#include <PubSubClient.h>

// Pin definitions
#define PIR_PIN 26
#define TRIG_PIN 4
#define ECHO_PIN 2
#define BUZZER_PIN 25

// WiFi credentials
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "test.mosquitto.org";

// MQTT topics
const char* pir_topic = "/Thinkitive/pir";
const char* distance_topic = "/Thinkitive/distance";

// Initialize WiFi and MQTT clients
WiFiClient espClient;
PubSubClient client(espClient);

// Variables for sensor readings and timing
unsigned long lastMsg = 0;
int pirState = LOW;
long distance = 0;

void setup_wifi() {
  Serial.println();
  Serial.print("Connecting to WiFi: ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  
  // Print the incoming message
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    
    // Generate client ID randomly
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);

    if (client.connect(clientId.c_str())) {
      Serial.println("Connected");
      
      // Publish a welcome message after connecting
      client.publish("/Thinkitive/Publish", "Welcome");
      
      // Subscribe to a topic
      client.subscribe("/Thinkitive/Subscribe");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  pinMode(PIR_PIN, INPUT);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(BUZZER_PIN, OUTPUT);

  Serial.begin(115200);
  setup_wifi();

  // Set MQTT server and callback function
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  
  // Publish sensor data every 2 seconds
  if (now - lastMsg > 2000) {
    lastMsg = now;

    // Read PIR sensor state
    pirState = digitalRead(PIR_PIN);

    // Determine the message to publish based on pirState
    const char* pirMessage;
    if (pirState == HIGH) {
      pirMessage = "Intruder detected";
    } else {
      pirMessage = "No intruder";
    }

    // Publish PIR sensor state
    client.publish(pir_topic, pirMessage);

    // Measure distance using ultrasonic sensor
    long duration, cm;
    digitalWrite(TRIG_PIN, LOW);
    delayMicroseconds(2);
    digitalWrite(TRIG_PIN, HIGH);
    delayMicroseconds(10);
    digitalWrite(TRIG_PIN, LOW);
    duration = pulseIn(ECHO_PIN, HIGH);
    cm = duration * 0.034 / 2;
    distance = cm;

    // Publish distance value
    client.publish(distance_topic, String(distance).c_str());

    // Debug prints
    Serial.print("PIR State: ");
    Serial.println(pirMessage);
    Serial.print("Distance: ");
    Serial.print(distance);
    Serial.println(" cm");
  }
}