#include <WiFi.h>
#include <PubSubClient.h>
#include "DHTesp.h"

// Thông tin kết nối WiFi
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Thông tin kết nối MQTT
const char* mqtt_server = "broker.emqx.io";
const char* SUBTOPIC_LED = "esp32-dht22/LED";
const char* SUBTOPIC_TEMP = "esp32-dht22/Temp";
const char* SUBTOPIC_HUMIDITY = "esp32-dht22/Humidity";

WiFiClient espClient;
PubSubClient client(espClient);

// Chân cho LED
const int LED_PIN = 13;

// Chân cho cảm biến DHT
const int DHT_PIN = 15;
DHTesp dhtSensor;

void setup_wifi() {
  // Hàm kết nối WiFi
  delay(10);
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  // Hàm kết nối lại MQTT
  while (!client.connected()) {
    Serial.println("Attempting MQTT connection...");
    String clientId = "mqttx_5d351537";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("Connected");
      client.subscribe(SUBTOPIC_LED);
    } else {
      delay(5000);
    }
  }
}

void callback(char *topic, byte *payload, unsigned int length) {
  // Hàm xử lý thông điệp MQTT
  Serial.print("Nhận chủ đề: ");
  Serial.println(topic);

  Serial.print("Nội dung: ");
  Serial.println((char *)payload);
  
  if (!strcmp(topic, SUBTOPIC_LED)) {
    if (!strncmp((char *)payload, "on", length)) {
      digitalWrite(LED_PIN, HIGH);
    } else if (!strncmp((char *)payload, "off", length)) {
      digitalWrite(LED_PIN, LOW);
    }
  }
}

void setup() {
  // Thiết lập chân và đối tượng khi bắt đầu chạy
  Serial.begin(115200);
  randomSeed(micros());

  pinMode(LED_PIN, OUTPUT);

  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);

  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

float old_temperature = 0;
float old_humidity = 0;

void loop() {
  // Vòng lặp chính
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  TempAndHumidity  data = dhtSensor.getTempAndHumidity();
  float temperature = data.temperature;
  float humidity = data.humidity;

  // Kiểm tra và xuất bản nhiệt độ
  if (old_temperature != temperature) {
    client.publish(SUBTOPIC_TEMP, String(temperature, 2).c_str());
  }
  old_temperature = temperature;

  // Kiểm tra và xuất bản độ ẩm
  if (old_humidity != humidity) {
    client.publish(SUBTOPIC_HUMIDITY, String(humidity, 1).c_str());
  }
  old_humidity = humidity;

  delay(1000);
}