//Sistem Kontrol Kipas Angin Otomatis dengan Sensor Suhu dan Sensor Ultrasonik

#include <Wire.h>
#include <Adafruit_Sensor.h>
#include <DHT.h>
#include <Adafruit_SSD1306.h>
#include <RTClib.h>

#define DHTPIN 8            // Pin untuk sensor DHT22
#define DHTTYPE DHT22      // Jenis sensor DHT22
#define TRIG_PIN 6         // Pin untuk TRIG sensor HC-SR04
#define ECHO_PIN 7         // Pin untuk ECHO sensor HC-SR04
#define RELAY_PIN 3        // Pin untuk Relay Module

// Definisikan ukuran OLED Display
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1

// Buat objek untuk OLED display dan RTC
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
RTC_DS1307 rtc;

DHT dht(DHTPIN, DHTTYPE);

// Konstanta
const int temperatureThreshold = 30; // Batas suhu untuk menghidupkan LED
const int distanceThreshold = 20;    // Threshold jarak untuk mendeteksi orang (20 cm)

void setup() {
  Serial.begin(9600);
  dht.begin();
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(RELAY_PIN, OUTPUT);
  digitalWrite(RELAY_PIN, LOW); // Matikan relay

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    for (;;);
  }

  if (!rtc.begin()) {
    Serial.println(F("Couldn't find RTC"));
    for (;;);
  }

  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0,0);
  display.println(F("Sistem Relay Otomatis"));
  display.display();

  delay(2000); // Tunggu 2 detik agar sensor DHT22 stabil
}

void loop() {
  float temperature = dht.readTemperature();
  long duration, distance;

  // Menghitung jarak menggunakan sensor ultrasonik
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  duration = pulseIn(ECHO_PIN, HIGH);
  distance = (duration / 2) * 0.0344;  // Menghitung jarak dalam cm
  
  // Deteksi apakah ada orang
  bool personDetected = distance <= distanceThreshold;

  // Menyalakan relay jika suhu melebihi batas atau ada orang terdeteksi
  if (temperature >= temperatureThreshold || personDetected) {
    digitalWrite(RELAY_PIN, HIGH);  // Nyalakan Kipas Angin
  } else {
    digitalWrite(RELAY_PIN, LOW);   // Matikan Kipas Angin
  }

  // Menampilkan suhu, jarak, dan status relay pada OLED
  display.clearDisplay();
  display.setCursor(0,0);
  display.print(F("Suhu: "));
  display.print(temperature);
  display.println(F(" C"));

  display.print(F("Jarak: "));
  display.print(distance);
  display.println(F(" cm"));

  display.print(F("Kipas Angin: "));
  if (digitalRead(RELAY_PIN) == HIGH) {
    display.println(F("NYALA"));
  } else {
    display.println(F("MATI"));
  }

  display.display();

  // Tampilkan data ke Serial Monitor
  Serial.print("Suhu: ");
  Serial.print(temperature);
  Serial.print(" C | ");
  Serial.print("Jarak: ");
  Serial.print(distance);
  Serial.print(" cm | ");
  Serial.print("Kipas Angin: ");
  if (digitalRead(RELAY_PIN) == HIGH) {
    Serial.println("NYALA");
  } else {
    Serial.println("MATI");
  }

  delay(2000); // Delay 2 detik
}