#include <Adafruit_Sensor.h>
#include <DHT.h>
#include <WiFi.h>
#include <PubSubClient.h>  //MQTT
#include <ESP32Servo.h>

#define DHTPIN 12
#define DHTTYPE DHT22
#define SERVO_PIN 2
#define LED_RED_PIN 26
#define LED_GREEN_PIN 25
#define LED_BLUE_PIN 33

// Servo
Servo servo;

// WiFi Configuration
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// MQTT Configuration
const char* mqttServer = "broker.hivemq.com";
const char* topic = "Tempdata";
const char* clientID = "ESP32-wokwi";

// Parameters for non-blocking delay
unsigned long previousMillis = 0;
const long interval = 1000;
String msgStr = "";
float temp, hum;

// DHT sensor object
DHT dht(DHTPIN, DHTTYPE);

// Setting up WiFi
WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
  delay(10);
  digitalWrite(LED_RED_PIN, HIGH);  // Red LED on when trying to connect to WiFi
  digitalWrite(LED_GREEN_PIN, LOW); // Green LED off initially
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  digitalWrite(LED_RED_PIN, LOW);   // Red LED off when WiFi is connected
  digitalWrite(LED_GREEN_PIN, HIGH); // Green LED on when WiFi is connected
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP Address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  while (!client.connected()) {
    if (client.connect(clientID)) {
      Serial.println("MQTT connected");
      client.subscribe("lights");
      client.subscribe("servo");
      client.subscribe("lights/neopixel");
      Serial.println("Topic Subscribed");
    } else {
      Serial.print("failed rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived in topic: ");
  Serial.println(topic);
  Serial.print("Message: ");
  String data = "";
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
    data += (char)payload[i];
  }
  Serial.println();
  Serial.print("Message size: ");
  Serial.println(length);
  Serial.println();
  Serial.println("-------------------------");
  Serial.print(data);

  if (String(topic) == "lights") {
    if (data == "ON") {
      Serial.print("LED");
      digitalWrite(LED_RED_PIN, LOW);
    } else {
      digitalWrite(LED_RED_PIN, HIGH);
    }
  } else if (String(topic) == "servo") {
    int degree = data.toInt();
    Serial.print("Moving servo to degree: ");
    Serial.println(degree);
    servo.write(degree);
  } 
}

void setup() {
  Serial.begin(115200);
  dht.begin(); // Initialize the DHT sensor
  pinMode(LED_RED_PIN, OUTPUT);
  pinMode(LED_GREEN_PIN, OUTPUT);
  pinMode(LED_BLUE_PIN, OUTPUT);
  digitalWrite(LED_RED_PIN, LOW);
  digitalWrite(LED_GREEN_PIN, LOW);
  digitalWrite(LED_BLUE_PIN, LOW);

  servo.attach(SERVO_PIN);
  servo.write(0);

  setup_wifi();
  client.setServer(mqttServer, 1883);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  unsigned long currentMillis = millis();
  if (currentMillis - previousMillis >= interval) {
    previousMillis = currentMillis;
    // Read temperature and humidity
    temp = dht.readTemperature();
    hum = dht.readHumidity();

    if (isnan(temp) || isnan(hum)) {
      Serial.println(F("Error reading temperature or humidity!"));
    } else {
      Serial.print(F("Temperature: "));
      Serial.print(temp);
      Serial.println(F("°C"));
      Serial.print(F("Humidity: "));
      Serial.print(hum);
      Serial.println(F("%"));

      msgStr = String(temp) + "," + String(hum);
      byte arrSize = msgStr.length() + 1;
      char msg[arrSize];
      Serial.print("PUBLISH DATA: ");
      Serial.println(msgStr);
      msgStr.toCharArray(msg, arrSize);
      client.publish(topic, msg);
      digitalWrite(LED_BLUE_PIN, HIGH);  // Blue LED on when data is published
      delay(500); // Delay to show blue LED status
      digitalWrite(LED_BLUE_PIN, LOW);   // Blue LED off
      msgStr = "";
    }
  }
}