#include <WiFi.h>
#include <PubSubClient.h>
#include "NMEA.h"
#include <ArduinoJson.h>
#include <time.h>

// WiFi credentials
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// MQTT broker
const char* mqtt_server = "52.186.84.10";
const char* mqtt_topic = "mitopico"; // Tema MQTT para publicar los datos GPS

// Pin mapping for GPS (simulated in Wokwi)
#define GPS_TX_PIN 17  // Pin TX del GPS simulado en Wokwi
#define GPS_RX_PIN 16  // Pin RX del GPS simulado en Wokwi

// Create an instance of the NMEA object
NMEA gps(GPRMC);

float latitude;
float longitude;
float speed;

// HardwareSerial for GPS
HardwareSerial SerialGPS(2);

// MQTT client setup
WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Conectando a ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi conectado");
  Serial.println("Dirección IP: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  // Esta función no se utilizará, ya que no se suscribirá a ningún tema
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Intentando conexión MQTT...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("Conectado");
    } else {
      Serial.print("Falló, estado=");
      Serial.print(client.state());
      Serial.println(" Intentando de nuevo en 5 segundos");
      delay(5000);
    }
  }
}

void publishGPSData() {
  if (gps.gprmc_status() == 'A') {
    speed = gps.gprmc_speed(KMPH);
  } else {
    speed = 0;
  }

  latitude = gps.gprmc_latitude();
  longitude = gps.gprmc_longitude();

  // Crea un mensaje JSON con los datos GPS
  DynamicJsonDocument doc(256);
  doc["Latitud"] = latitude;
  doc["Longitud"] = longitude;
  doc["Velocidad"] = speed;
  doc["Timestamp"] = time(NULL);

  // Publica el mensaje JSON en el tema MQTT
  char buffer[256];
  serializeJson(doc, buffer);
  client.publish(mqtt_topic, buffer);

  // Para depuración
  Serial.println();
  Serial.print("Latitud: ");
  Serial.println(latitude, 6);
  Serial.print("Longitud: ");
  Serial.println(longitude, 6);
  Serial.print("Velocidad: ");
  Serial.println(speed);
  Serial.print("Timestamp: ");
  Serial.println(doc["Timestamp"].as<long>());
}

void setup() {
  Serial.begin(115200);
  SerialGPS.begin(9600, SERIAL_8N1, GPS_RX_PIN, GPS_TX_PIN);

  setup_wifi(); 

  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);

  Serial.println("Datos recibidos desde GPS simulado en Wokwi:");
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  while (SerialGPS.available()) {
    char serialData = SerialGPS.read();
    Serial.print(serialData);

    if (gps.decode(serialData)) {
      publishGPSData();
    }
  }

  // Añadir un pequeño delay para evitar posibles problemas de watchdog
  delay(10);
}