/* Lab Trial Test 2
 * Name: CHIA HOOI BOOY
 * Class: DEEC2
 * Date: 10-July-2024
 */

#include <WiFi.h>
#include <PubSubClient.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqtt_server = "broker.hivemq.com";
const char* clientName = "maymaychia"; // Replace with your unique client ID
const int mqtt_port = 1883;

WiFiClient espClient;
PubSubClient client(espClient);

const int led_red = 23; // GPIO pin for red LED
int led_red_state = LOW;

const int adcPin = A5; // ADC pin (A5 corresponds to pin 33 on ESP32)

long previousMillis = 0;
const long led_interval = 2000; // Blink interval for LED (ms)

const long adc_interval = 500; // Interval for publishing ADC value (ms)
long previousAdcMillis = 0;
long adcValue;

void setup_wifi() {
  Serial.begin(115200);
  delay(100);
  
  WiFi.begin(ssid, password);
  Serial.println();

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println();
  Serial.print("WiFi connected, IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect(clientName)) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  pinMode(led_red, OUTPUT);
  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  long currentMillis = millis();

  // Blink LED every led_interval milliseconds
  if (currentMillis - previousMillis >= led_interval) {
    previousMillis = currentMillis;

    if (led_red_state == LOW) {
      led_red_state = HIGH;
    } else {
      led_red_state = LOW;
    }
    digitalWrite(led_red, led_red_state);
  }

  // Read ADC value every adc_interval milliseconds and publish
  if (currentMillis - previousAdcMillis >= adc_interval) {
    previousAdcMillis = currentMillis;
    adcValue = analogRead(adcPin);
    Serial.print("ADC value = ");
    Serial.println(adcValue);

    char adcStr[10];
    itoa(adcValue, adcStr, 10); // Convert ADC value to string

    client.publish("IOT/3840032A/red", adcStr); // Publish ADC value to MQTT topic
  }
}