#include <WiFi.h>
#include <ThingsBoard.h>
#include <Arduino_MQTT_Client.h>
#include <OneWire.h>
#include <DallasTemperature.h>
#include <PubSubClient.h>
#include <ArduinoHttpClient.h>

// Define sound speed in cm/uS
#define SOUND_SPEED 0.034
#define CM_TO_INCH 0.393701

// ThingsBoard server details
#define TB_SERVER "thingsboard.cloud"
#define TB_TOKEN "MDgjHN9ZKmhbOBRLR93x"

// WiFi credentials
#define WIFI_AP "Wokwi-GUEST"
#define WIFI_PASS ""

// Pin definitions
const int trigPin = 19;
const int echoPin = 18;
const int oneWireBus = 12; // GPIO where the DS18B20 is connected

// Initialize DS18B20 temperature sensor
OneWire oneWire(oneWireBus);
DallasTemperature sensors(&oneWire);

constexpr uint16_t MAX_MESSAGE_SIZE = 128U;

// Sensor -> ESP32 -> WiFi Client -> Arduino_MQTT_Client -> TB 
WiFiClient espClient;
Arduino_MQTT_Client mqttClient(espClient);
ThingsBoard tb(mqttClient, MAX_MESSAGE_SIZE);

long duration;
float distanceCm;
float distanceInch;
float temperatureC;

void setup() {
  // Start serial communication
  Serial.begin(115200);

  // Initialize pins
  pinMode(trigPin, OUTPUT); // Sets the trigPin as an Output
  pinMode(echoPin, INPUT);  // Sets the echoPin as an Input
  
  // Start the DS18B20 sensor
  sensors.begin();

  // Connect to WiFi
  WiFi.begin(WIFI_AP, WIFI_PASS);
  Serial.println("Connecting to WiFi...");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nWiFi connected!");
  Serial.print("IP Address: ");
  Serial.println(WiFi.localIP());

  // Connect to ThingsBoard
  Serial.println("Connecting to ThingsBoard Server....");
  while (!tb.connect(TB_SERVER, TB_TOKEN)) {
    Serial.println("Failed to connect to ThingsBoard...");
    delay(500);
  }
  Serial.println("Connected to ThingsBoard...");
}

void loop() {
  // Measure distance with ultrasonic sensor
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);
  
  duration = pulseIn(echoPin, HIGH);
  distanceCm = duration * SOUND_SPEED / 2;
  distanceInch = distanceCm * CM_TO_INCH;

  // Print distance to serial monitor
  Serial.print("Distance (cm): ");
  Serial.println(distanceCm);
  Serial.print("Distance (inch): ");
  Serial.println(distanceInch);

  // Send distance data to ThingsBoard
  String jsonData = "{\"Distance\":" + String(distanceCm) + "}";
  tb.sendTelemetryJson(jsonData.c_str());
  Serial.println("Distance (cm) data is passed to ThingsBoard");

  String jsonData1 = "{\"Distance_INCH\":" + String(distanceInch) + "}";
  tb.sendTelemetryJson(jsonData1.c_str());
  Serial.println("Distance (inch) data is passed to ThingsBoard");

  // Measure temperature with DS18B20
  sensors.requestTemperatures();
  temperatureC = sensors.getTempCByIndex(0);

  // Print temperature to serial monitor
  Serial.print("Temperature (°C): ");
  Serial.println(temperatureC);

  // Send temperature data to ThingsBoard
  String jsonTempData = "{\"Temperature\":" + String(temperatureC) + "}";
  tb.sendTelemetryJson(jsonTempData.c_str());
  Serial.println("Temperature data is passed to ThingsBoard");

  delay(1000); // Wait for a second before the next loop
}


//https://wokwi.com/projects/403185009406746625