// Agregamos las librerías a usar
#include <WiFi.h>
#include <PubSubClient.h>
#include "DHTesp.h"

// Establecemos la comunicación WiFi
const char* ssid = "Wokwi-GUEST";
const char* password = "";


// Inicializamos el broker MQTT disponible para Adafruit IO
const char* mqtt_server = "io.adafruit.com";
const char* mqtt_username = "Sybitas";
const char* mqtt_password = "aio_etDe64H0HEdXAzat8khz3zCTVBwa";

// Generamos los tópicos a usar
const char* SUBTOPIC_TEMP = "Sybitas/f/Temp";
const char* SUBTOPIC_HUMIDITY = "Sybitas/f/Humid";

WiFiClient espClient;
PubSubClient client(espClient);

// Configuramos los pines del esp32 para el DHT
const int DHT_PIN = 15;
DHTesp dhtSensor;

// Inicializamos la conexión a internet
void setup_wifi() {
  delay(10);
  Serial.print("Conectando a ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi conectado");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

// Inicializamos la conexión al broker MQTT
void reconnect() {
  while (!client.connected()) {
    Serial.print("Intentando conexión MQTT...");
    String clientId = "esp32-dht22-clientid-";
    clientId += String(random(0xffff), HEX);

    if (client.connect(clientId.c_str(), mqtt_username, mqtt_password)) {
      Serial.println("Conectado");
    } else {
      Serial.print("Conexión fallida, rc=");
      Serial.print(client.state());
      Serial.println(" Intentando en 5 segundos");
      delay(5000);
    }
  }
}

// Inicializamos las configuraciones básicas del programa
void setup() {
  Serial.begin(115200);
  randomSeed(micros());

  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);

  setup_wifi();
  client.setServer(mqtt_server, 1883);
  // client.setCallback(callback);
}

float old_temperature = 0;
float old_humidity = 0;

// Generamos bucle que publique la temperatura y humedad cuando su valor es actualizado
void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  TempAndHumidity data = dhtSensor.getTempAndHumidity();
  float temperature = data.temperature;
  float humidity = data.humidity;

  if (old_temperature != temperature) {
    client.publish(SUBTOPIC_TEMP, String(temperature, 2).c_str());
    old_temperature = temperature;
  }

  if (old_humidity != humidity) {
    client.publish(SUBTOPIC_HUMIDITY, String(humidity, 1).c_str());
    old_humidity = humidity;
  }

  delay(3000);
}