#define BLYNK_TEMPLATE_ID "TMPL69QwprBuZ"
#define BLYNK_TEMPLATE_NAME "ESP32 DHT22"
#define BLYNK_AUTH_TOKEN "OAptOtYtvyxE9AjpY98DoWYzmgw_F426"

#define BLYNK_PRINT Serial

#include <WiFi.h>
#include <WiFiClient.h>
#include <BlynkSimpleEsp32.h>
#include <DHT.h>

char auth[] = BLYNK_AUTH_TOKEN;
char ssid[] = "Wokwi-GUEST"; // Nama hotspot yang digunakan
char pass[] = "";            // Password hotspot yang digunakan

#define DHTPIN 5      // Pin digital tempat Anda menghubungkan DHT
#define DHTTYPE DHT22 // Jenis sensor DHT (misalnya DHT11 atau DHT22)
DHT dht(DHTPIN, DHTTYPE);
BlynkTimer timer;

const int mq135Pin = 34;   // Pin analog yang terhubung ke AOUT sensor MQ-135
const int buzzerPin = 32;  // Pin yang terhubung ke buzzer
const int ledPin1 = 19;    // Pin yang terhubung ke LED 1 (untuk suhu di atas 35 derajat)
const int ledPin2 = 18;    // Pin yang terhubung ke LED 2 (untuk humidity di bawah 30%)
bool buzzerOn = false;     // Variabel untuk menyimpan status bunyi buzzer
bool ledOn1 = false;       // Variabel untuk menyimpan status LED 1
bool ledOn2 = false;       // Variabel untuk menyimpan status LED 2
bool programActive = true; // Variabel untuk status program (ON/OFF)

// Fungsi untuk menangani perubahan status tombol program (ON/OFF)
BLYNK_WRITE(V3) {
  programActive = param.asInt();
  Serial.print("Program status: ");
  Serial.println(programActive ? "ON" : "OFF");
}

void setup() {
  Serial.begin(115200);
  Blynk.begin(auth, ssid, pass);
  dht.begin();
  timer.setInterval(2500L, sendSensor);

  pinMode(buzzerPin, OUTPUT); // Inisialisasi pin buzzer sebagai output
  pinMode(ledPin1, OUTPUT);   // Inisialisasi pin LED 1 sebagai output
  pinMode(ledPin2, OUTPUT);   // Inisialisasi pin LED 2 sebagai output
}

void loop() {
  Blynk.run();
  timer.run();
}

void sendSensor() {
  if (!programActive) {
    // Jika program tidak aktif, matikan semua output dan kembali
    digitalWrite(buzzerPin, LOW);
    digitalWrite(ledPin1, LOW);
    digitalWrite(ledPin2, LOW);
    buzzerOn = false;
    ledOn1 = false;
    ledOn2 = false;
    return;
  }

  float h = dht.readHumidity();
  float t = dht.readTemperature(); // or dht.readTemperature(true) for Fahrenheit
  if (isnan(h) || isnan(t)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  Blynk.virtualWrite(V1, h);
  Blynk.virtualWrite(V0, t);
  Serial.print("Temperature : ");
  Serial.print(t);
  Serial.print("    Humidity : ");
  Serial.println(h);

  // Kirim log jika suhu lebih dari 30 derajat Celsius
  if (t > 30) {
    // Blynk.email("[email protected]", "Alert", "Temperature over 30C!");
    Blynk.logEvent("temp_alert", "Temp above 30 degrees");
  }

  // Menghitung PPM dari sensor MQ-135
  int mq135Value = analogRead(mq135Pin);
  float voltage = mq135Value * (3.3 / 4095.0);
  int ppm = map(mq135Value, 0, 4095, 0, 1000); // Perkiraan PPM (tidak akurat)

  Blynk.virtualWrite(V2, ppm); // Mengirim nilai PPM ke Blynk
  Serial.print("CO2 PPM: ");
  Serial.println(ppm);

  // Aktifkan atau matikan buzzer jika PPM mencapai 250
  if (ppm >= 250 && !buzzerOn) {
    digitalWrite(buzzerPin, HIGH); // Aktifkan buzzer
    buzzerOn = true;               // Update status bunyi buzzer
    Serial.println("Danger: High CO2 Level!");
  } else if (ppm < 250 && buzzerOn) {
    digitalWrite(buzzerPin, LOW);  // Matikan buzzer
    buzzerOn = false;              // Update status bunyi buzzer
  }

  // Aktifkan atau matikan LED 1 jika suhu di atas 35 derajat Celsius
  if (t > 35 && !ledOn1) {
    digitalWrite(ledPin1, HIGH); // Nyalakan LED 1
    ledOn1 = true;               // Update status LED 1
    Serial.println("High Temperature: LED 1 ON");
  } else if (t <= 35 && ledOn1) {
    digitalWrite(ledPin1, LOW);  // Matikan LED 1
    ledOn1 = false;              // Update status LED 1
  }

  // Aktifkan atau matikan LED 2 jika humidity di bawah 30%
  if (h < 30 && !ledOn2) {
    digitalWrite(ledPin2, HIGH); // Nyalakan LED 2
    ledOn2 = true;               // Update status LED 2
    Serial.println("Low Humidity: LED 2 ON");
  } else if (h >= 30 && ledOn2) {
    digitalWrite(ledPin2, LOW);  // Matikan LED 2
    ledOn2 = false;              // Update status LED 2
  }
}