/**
   Eight-key piano for Arduino Uno

   You can control the colorful buttons with your keyboard:
   After starting the simulation, click anywhere in the diagram to focus it.
   Then press any key between 1 and 8 to play the piano (1 is the lowest note,
   8 is the highest).

   Original code was copyright (C) 2021, Uri Shaked. Released under the MIT License.
   Original code is found here: https://wokwi.com/projects/291958456169005577

   Uri Shaked's code was heavily modified by Dr. Scott Feister, July 19, 2024
   for CS M125 at Moorpark College in California.
   The goal of this modified code is to teach students about C-style arrays.
*/

// NOTE FROM DR. FEISTER
// The Arduino IDE hides some include statements from the programmer.
// One include statement gives you access to all methods defined at https://www.arduino.cc/reference/en/
// If you could see this hidden include statement, it would look something like this:
/*
#include "arduino.h"
*/

/********* PIN ASSIGNMENT **********/

// Digital Pin 8 on your Arduino Uno is connected to a buzzer speaker
// (buzzes at different frequencies to create different tones)
#define BUZZER_PIN 8

// Digital Pins 12,11,10,9,7,6,5,4 on your Arduino Uno are connected to piano buttons
// (Note that Digital Pin 8 is skipped since it is already in use by the buzzer speaker)
const int PIANO_PINS[] = {12, 11, 10, 9, 7, 6, 5, 4};

// Musical notes for the piano keys
// C4 (C tone, fourth octave) is created by buzzing the buzzer at 262 Hz
// D4 (D tone, fourth octave) is created by buzzing the buzzer at 294 Hz
// E4 (E tone, fourth octave) is created by buzzing the buzzer at 330 Hz
// ...
// C5 (C tone, fifth octave) is created by buzzing the buzzer at 523 Hz

const int NOTES[] = {262, 294, 330, 349, 392, 440, 494, 523};

/********* DEVICE INITIALIZATION FUNCTIONS **********/

void initPianoKey(int pin) {
  // Initialize one piano key
  pinMode(pin, INPUT_PULLUP);
}

void initBuzzer(int pin) {
  // Initialize the buzzer speaker
  pinMode(pin, OUTPUT);
}

bool isKeyPressed(int pin) {
  // Check if key is depressed
  return digitalRead(pin) == LOW; // true if key is currently depressed
  }
}

/********* REQUIRED ARDUINO FUNCTIONS *********/

// In Arduino, the setup() method runs first, once per power cycle of the Arduino
void setup() {
  for (int i = 0; i < 8; i++) {
    initPianoKey(PIANO_PINS[i]);
  }
  initBuzzer(BUZZER_PIN); // buzzer speaker
}

// In Arduino, the loop() method is repeatedly called in an infinite while loop, once setup is completed

void loop() {
  bool keyPressed = false; //true if *any* piano key is currently pressed
                           // initialized to "false" and then is
                           // re-assigned to "true" if key press is detected

  //check whether any piano keys are depressed, and buzz accordingly
  for (int i = 0; i < 8; i++) {
    if (isKeyPressed(PIANOPINS[i])) { // piano key #i is pressed
      tone(BUZZER_PIN, NOTES[i]); // buzz out the musical note corresponding to piano key #i
      keyPressed = true;
      break; // exit the loop once a key is found pressed
    }
  }
  if (!keyPressed) { //no keys are pressed
    noTone(BUZZER_PIN); // silence the buzzer speaker
  }
}


/********* MAIN FUNCTION (Hidden) *********/

// NOTE FROM DR. FEISTER
// The Arduino IDE hides the main() function from the programmer.
// If you could see the main function, it would look something like this:
/*
int main() {
  setup();
  while (true) {
    loop();
  }
}
*/