#include <WiFi.h>
#include <WiFiClient.h>
#include <PubSubClient.h>
#include <DHT.h>

// Wi-Fi credentials
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* hostname = "broker.hivemq.com";

// MQTT client name and port
WiFiClient espClient;
PubSubClient client(espClient);
const char* espClientName = "esp32Client_ADC/LT50/5036200U"; // yourStudentID must be unique
int PORTNUM = 1883;

// Define sensor pins
#define LDR_PIN 35  // GPIO35 for analog input
#define DHT_PIN 32   // GPI32 for DHT22
#define POT_PIN 33  // GPIO33 for analog input

// Create DHT sensor instance
DHT dht(DHT_PIN, DHT22);

// Timing variables
long previousMillis = 0;
const long interval = 2000; // Interval to publish sensor data (2 seconds)

void setup_wifi() 
{
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) 
  {
    delay(1000);
    Serial.print(".");
  }
  Serial.println();
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("Given IP by the router to ESP32 is ");
  Serial.println(WiFi.localIP());
}

void connectMQTT() 
{
  while (!client.connected())
   {
    Serial.println("Connecting to MQTT ...");
    if (client.connect(espClientName))
    {
      Serial.println("Connected");
      MQTTSubscribe();
    } else 
    {
      Serial.print("Failed with state ");
      Serial.print(client.state());
      delay(2000);
    }
  }
}

void callback(String topic, byte* payload, unsigned int length) 
{
  // Process incoming messages
  String messageTemp;
  Serial.print("Message received in topic: ");
  Serial.print(topic);
  Serial.print(" length is: ");
  Serial.println(length);

  Serial.print("Data received from broker: ");
  for (int i = 0; i < length; i++) 
  {
    Serial.print((char)payload[i]);
    messageTemp += (char)payload[i];
  }

}

void MQTTSubscribe() 
{
  client.subscribe("ADC/LT50/5036200U");
}

void setup_MQTT() 
{
  client.setServer(hostname, PORTNUM);
  client.setCallback(callback);
}

void setup() 
{
  Serial.begin(115200);
  setup_wifi();
  setup_MQTT();
  dht.begin();

}

void loop() 
{
  if (!client.connected()) 
  {
    connectMQTT();
  }
  client.loop();

  long currentMillis = millis();
  if (currentMillis - previousMillis >= interval) 
  {
    previousMillis = currentMillis;
    
    // Read sensor values
    int ldrValue = analogRead(LDR_PIN);
    float humidity = dht.readHumidity();
    float temperature = dht.readTemperature();
    int potValue = analogRead(POT_PIN);

    // Check if any reads failed and exit early (to try again)
    if (isnan(humidity) || isnan(temperature)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
    }

    // Print sensor values to serial monitor
    Serial.print("LDR: "); Serial.println(ldrValue);
    Serial.print("Humidity: "); Serial.print(humidity); Serial.println(" %");
    Serial.print("Temperature: "); Serial.print(temperature); Serial.println(" *C");
    Serial.print("Potentiometer: "); Serial.println(potValue);

    // Create a JSON payload
    String payload = "{";
    payload += "\"ldr\":" + String(ldrValue) + ",";
    payload += "\"humidity\":" + String(humidity) + ",";
    payload += "\"temperature\":" + String(temperature) + ",";
    payload += "\"potentiometer\":" + String(potValue);
    payload += "}";

    // Publish payload to MQTT broker
    client.publish("ADC/LT50/5036200U", payload.c_str());
  }
}