#include <WiFi.h>
#include <WiFiClient.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <DHT.h>

#define DHT_TYPE DHT22
#define DHT_PIN 4

DHT dht(DHT_PIN, DHT_TYPE);
LiquidCrystal_I2C lcd(0x27, 16, 2);

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* hostname = "broker.hivemq.com";
WiFiClient espClient;
PubSubClient client(espClient);
const char* espClientName = "IOT/PROJECT";
int PORTNUM = 1883;

unsigned long previousMillis = 0;
const unsigned long interval = 2000;

// Flags to override local controls
bool ACState = LOW;
bool humidityState = LOW;
bool ACOverride = false;
bool humidityOverride = false;

void setup_wifi()
{
  WiFi.begin(ssid, password);
  while(WiFi.status() != WL_CONNECTED)
  {
    delay(1000);
    Serial.print(".");
  }
  Serial.println();
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP assigned to ESP32: ");
  Serial.println(WiFi.localIP());
}

void connectMQTT()
{
  while(!client.connected())
  {
    Serial.println("Connecting to MQTT...");
    if (client.connect(espClientName))
    {
      Serial.println("Connected");
      MQTTSubscribe();
    }
    else
    {
      Serial.print("Failed with state ");
      Serial.println(client.state());
      delay(2000);
    }
  }
}

void callback(char* topic, byte* payload, unsigned int length)
{
  String messageTemp;
  for (int i = 0; i < length; i++)
  {
    messageTemp += (char)payload[i];
  }

  if (String(topic) == "IOT/PROJECT/AC")
  {
    if (messageTemp == "ON")
    {
      ACState = HIGH;
      ACOverride = true;
      digitalWrite(25, ACState);
      Serial.println("AC turned ON via MQTT PANEL");
    }
    else if (messageTemp == "OFF")
    {
       ACState = LOW;
      ACOverride = true;
      digitalWrite(25, ACState);
      Serial.println("AC turned OFF via MQTT PANEL");
    }
  }
  else if (String(topic) == "IOT/PROJECT/HUMIDITY")
  {
    if (messageTemp == "ON")
    { 
      humidityState = HIGH;
      humidityOverride = true; 
      digitalWrite(26, humidityState); 
      Serial.println("Humidifier turned ON via MQTT PANEL");
    }
    else if (messageTemp == "OFF")
    { 
      humidityState = LOW;
      humidityOverride = true; 
      digitalWrite(26, humidityState); 
      Serial.println("Humidifier turned OFF via MQTT PANEL");
    }
  }
}

void setup_MQTT()
{
  client.setServer(hostname, PORTNUM);
  client.setCallback(callback);
}

void MQTTSubscribe()
{
  client.subscribe("IOT/PROJECT/AC");
  client.subscribe("IOT/PROJECT/HUMIDITY");
}

void setup()
{
  Serial.begin(115200);
  pinMode(25, OUTPUT); // For temperature indicator
  pinMode(26, OUTPUT); // For humidity indicator

  Wire.begin(21, 22);
  lcd.init();
  lcd.backlight();
  dht.begin();

  setup_wifi();
  setup_MQTT();
}

void loop()
{
  if (!client.connected())
  {
    connectMQTT();
  }
  client.loop();

  unsigned long currentMillis = millis();
  if (currentMillis - previousMillis >= interval)
  {
    previousMillis = currentMillis;
    float temperature = dht.readTemperature();
    float humidity = dht.readHumidity();

    if (isnan(temperature) || isnan(humidity))
    {
      Serial.println("Failed to read from DHT sensor!");
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("DHT Error");
    }
    else
    {
      Serial.print("Temperature: ");
      Serial.print(temperature);
      Serial.print(" *C ");
      Serial.print("Humidity: ");
      Serial.print(humidity);
      Serial.println(" %");
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Temp: ");
      lcd.print(temperature);
      lcd.print(" C");
      lcd.setCursor(0, 1);
      lcd.print("Humidity: ");
      lcd.print(humidity);
      lcd.print(" %");

      // Control lights based on sensor data only if not overridden by MQTT
      if (!ACOverride)
      {
        if (temperature > 26.0)
        {
          ACState = HIGH;// Turn on temperature indicator light
          Serial.println("Temperature > 26C. Turning on AC.");
        }
        else
        {
          ACState = LOW;// Turn off temperature indicator light
          Serial.println("Temperature <= 26C. Turning off AC.");
        }
        digitalWrite(25, ACState);
      }

      if (!humidityOverride)
      {
        if (humidity < 30.0)
        {
          humidityState = HIGH; // Turn on humidity indicator light
          Serial.println("Humidity < 30%. Turning on Humidifier.");
        }
        else
        {
          humidityState = LOW; // Turn off humidity indicator light
          Serial.println("Humidity >= 30%. Turning off Humidifier.");
        }
        digitalWrite(26, humidityState);
      }
    }
  }
}