#include <WiFi.h> 
#include <WiFiClient.h>
#include <PubSubClient.h> // MQTT messages in out
#include <Wire.h> // i2c communication
#include <LiquidCrystal_I2C.h> //include the servo library 
#include <DHT.h> //include the DTH22 library 

//defining Pins 
#define DHT_TYPE DHT22
#define DHT_PIN 4
// DHT parameter 
DHT dht(DHT_PIN, DHT_TYPE);
LiquidCrystal_I2C lcd(0x27, 16, 2);

// Setting AP SSID 
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* hostname = "broker.hivemq.com"; //Broker
const char* espClientName = "IOT/PROJECT"; //Publish topic
int PORTNUM = 1883;

// Setting up wifi and MQTT client
WiFiClient espClient;
PubSubClient client(espClient);

//Parameter for using non-blocking delay
unsigned long previousMillis = 0;
const unsigned long interval = 2000; 

//Function setup WIFI
void setup_wifi()
{
  WiFi.begin(ssid, password);
  while(WiFi.status() != WL_CONNECTED)
  {
    delay(1000);
    Serial.print(".");
  }
  Serial.println();
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP assigned to ESP32: ");
  Serial.println(WiFi.localIP());
}

// Connect Function MQTT
void connectMQTT()
{
  while(!client.connected())
  {
    Serial.println("Connecting to MQTT...");
    if (client.connect(espClientName))
    {
      Serial.println("Connected");
      MQTTSubscribe();
    }
    else
    {
      Serial.print("Failed with state ");
      Serial.println(client.state());
      delay(2000); 
    }
  }
}

//Function callback when any msg arrival on any subscrib topic 
void callback(char* topic, byte* payload, unsigned int length)
{
   String messageTemp;
   
  for (int i = 0; i < length; i++)
  {
    Serial.print((char)payload[i]);
    messageTemp += (char)payload[i];
  }

  Serial.println();

  if (String(topic) == "IOT/PROJECT/AC")
  {
    if (messageTemp == "ON")
    {
      digitalWrite(25, HIGH); 
      Serial.println("AC turned ON via MQTT PANEL");
    }
    else if (messageTemp == "OFF")
    {
      digitalWrite(25, LOW); 
      Serial.println("AC turned OFF via MQTT PANEL");
    }
  }
  else if (String(topic) == "IOT/PROJECT/HUMIDITY")
  {
    if (messageTemp == "ON")
    {
      digitalWrite(26, HIGH); 
      Serial.println("Humidifier turned ON via MQTT PANEL");
    }
    else if (messageTemp == "OFF")
    {
      digitalWrite(26, LOW); 
      Serial.println("Humidifier turned OFF via MQTT PANEL");
    }
  }
}

void setup_MQTT()
{
  client.setServer(hostname, PORTNUM); //Setting MQTT server
  client.setCallback(callback); // define function which will be called 
}

void MQTTSubscribe()
{
  client.subscribe("IOT/PROJECT/AC");
  client.subscribe("IOT/PROJECT/HUMIDITY");
}

void setup()
{
  Serial.begin(115200); 
  pinMode(25, OUTPUT); // For temperature indicator
  pinMode(26, OUTPUT); // For humidity indicator

  Wire.begin(21, 22);
  lcd.init();
  lcd.backlight();
  dht.begin();

  setup_wifi();
  setup_MQTT();
}

void loop()
{
  if (!client.connected())
  {
    connectMQTT();
  }
  client.loop();

  unsigned long currentMillis = millis();
  if (currentMillis - previousMillis >= interval)
  {
    previousMillis = currentMillis;
    float temperature = dht.readTemperature();
    float humidity = dht.readHumidity();

//get temperature ,humidity event and print its value
    if (isnan(temperature) || isnan(humidity))
    {
      Serial.println("Failed to read from DHT sensor!");
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("DHT Error");
    }
    else
    {
      Serial.print("Temperature: ");
      Serial.print(temperature);
      Serial.print(" *C ");
      Serial.print("Humidity: ");
      Serial.print(humidity);
      Serial.println(" %");
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Temp: ");
      lcd.print(temperature);
      lcd.print(" C");
      lcd.setCursor(0, 1);
      lcd.print("Humidity: ");
      lcd.print(humidity);
      lcd.print(" %");

      // Control lights based on sensor data
      if (temperature > 26.0)
      {
        digitalWrite(25, HIGH); // Turn on temperature indicator light
        Serial.println("Temperature > 26C. Turning on AC.");
      }
      else
      {
        digitalWrite(25, LOW); // Turn off temperature indicator light
        Serial.println("Temperature <= 26C. Turning off AC.");
      }

      if (humidity < 30.0)
      {
        digitalWrite(26, HIGH); // Turn on humidity indicator light
        Serial.println("Humidity < 30%. Turning on Humidifier.");
      }
      else
      {
        digitalWrite(26, LOW); // Turn off humidity indicator light
        Serial.println("Humidity >= 30%. Turning off Humidifier.");
      }
    }
  }
}