#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

#define DHTPIN 25
#define DHTTYPE DHT22
#define LYUNO 17
#define LRUNO 16
#define LYDOS 13
#define LRDOS 12
#define RELAY_PIN 14

const char* ssid = "Wokwi-GUEST"; // WiFi simulada de Wokwi
const char* password = ""; // Sin contraseña para Wokwi-GUEST
const char* mqtt_server = "broker.hivemq.com";
const char* topic_led = "testtopic/led";
const char* topic_data = "testtopic/humedad";

WiFiClient espClient;
PubSubClient client(espClient);
DHT dht(DHTPIN, DHTTYPE);  // Inicialización correcta

long lastMsg = 0;
char msg[50];
float temp = 0.0;
float humidity = 0.0;

void setup() {
  // Configuración de pines
  pinMode(LYUNO, OUTPUT);
  pinMode(LRUNO, OUTPUT);
  pinMode(LYDOS, OUTPUT);
  pinMode(LRDOS, OUTPUT);
  pinMode(RELAY_PIN, OUTPUT);

  digitalWrite(LYUNO, LOW);
  digitalWrite(LRUNO, LOW);
  digitalWrite(LYDOS, LOW);
  digitalWrite(LRDOS, LOW);
  digitalWrite(RELAY_PIN, LOW);

  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);

  dht.begin();
}

void setup_wifi() {
  Serial.begin(115200);
  WiFi.begin(ssid, password);

  Serial.print("Connecting to ");
  Serial.print(ssid);

  int attempts = 0;
  while (WiFi.status() != WL_CONNECTED && attempts < 20) {
    delay(500);
    Serial.print(".");
    attempts++;
  }

  if (WiFi.status() == WL_CONNECTED) {
    Serial.println("\nConnected successfully");
    Serial.print("IP Address: ");
    Serial.println(WiFi.localIP());
  } else {
    Serial.println("\nFailed to connect");
  }
}

void callback(char* topic, byte* payload, unsigned int length) {
  String messageTemp;

  for (int i = 0; i < length; i++) {
    messageTemp += (char)payload[i];
  }

  if (String(topic) == topic_led) {
    if (messageTemp == "YELLOW_ON") {
      digitalWrite(LYDOS, HIGH);
      digitalWrite(LRDOS, LOW);
    } else if (messageTemp == "RED_ON") {
      digitalWrite(LYDOS, LOW);
      digitalWrite(LRDOS, HIGH);
    }
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect("ESP32Client")) {
      Serial.println("connected");
      client.subscribe(topic_led);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  long now = millis();
  if (now - lastMsg > 60000) {
    lastMsg = now;

    temp = dht.readTemperature();
    humidity = dht.readHumidity();

    if (isnan(temp) || isnan(humidity)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
    }

    if (temp < 22) {
      digitalWrite(LYUNO, HIGH);
      digitalWrite(LRUNO, LOW);
    } else if (temp > 50) {
      digitalWrite(LYUNO, LOW);
      digitalWrite(LRUNO, HIGH);
    } else {
      digitalWrite(LYUNO, LOW);
      digitalWrite(LRUNO, LOW);
    }

    if (humidity < 60) {
      digitalWrite(RELAY_PIN, HIGH);
    } else if (humidity >= 90) {
      digitalWrite(RELAY_PIN, LOW);
    }

    String payload = "Temp: " + String(temp) + " C, Humidity: " + String(humidity) + " %";
    payload.toCharArray(msg, 50);
    client.publish(topic_data, msg);
  }
}