# Welcome to The Bin! 🦝

Now that you've thrown some parts into The Bin, it's time to turn that trash into treasure! 🗑️➡️💎

Wire up your parts and write some code to make them work together. If you need
help with a part, click the "?" above it.

If you want to see examples, check here:
https://hack.club/bin-example

You can get help by chatting with other high schoolers on the Hack Club Slack in
the #electronics channel:
👉 https://hackclub.com/slack 👈

Once you're ready build your design IRL, click the "Share" button and submit
your design:
https://hack.club/bin-submit
    

help.md

// Now turn this trash into treasure!
#define DECODE_NEC // Decode NEC remote codes
#include <SPI.h>
#include <Wire.h>
#include <Adafruit_NeoPixel.h>
#include <SSD1306Ascii.h>
#include <SSD1306AsciiWire.h>
#include <IRremote.h>

// ----- DEVICE CONFIGURATION -----
// 0X3C+SA0 - 0x3C or 0x3D
#define DISPLAY_I2C_ADDRESS 0x3C

// Define proper RST_PIN if required.
#define RST_PIN -1

// What pin are the NeoPixels connected to?
#define LED_PIN 28
// How many NeoPixels are attached to the Arduino?
#define LED_COUNT 1

#define RECIEVER_PIN 26   // Signal Pin of IR receiver

#define RELAY_PIN 27 // Input pin to the relay

// Declare our NeoPixel strip object:
Adafruit_NeoPixel strip(LED_COUNT, LED_PIN, NEO_GRB + NEO_KHZ800);

// Declare an object for the OLED
SSD1306AsciiWire oled;

// IR Reciever
IRrecv receiver(RECIEVER_PIN);

bool switch_on = false;
bool button_pressed = false;

void updateOutput() {
  oled.clear();
  if (switch_on) {
    oled.println("Power On");
    strip.setPixelColor(0, 255, 255, 255);
    digitalWrite(RELAY_PIN, HIGH);
  } else {
    oled.println("Power Off");
    strip.setPixelColor(0, 0, 0, 0);
    digitalWrite(RELAY_PIN, LOW);
  }
  strip.show(); // Initialize LEDs
}

void toggleSwitch() {
  switch_on = !switch_on;
  updateOutput();
}

void setup() {
  // put your setup code here, to run once:
  Serial1.begin(115200);

  Wire.begin();
  Wire.setClock(400000L);

  strip.begin();
  strip.setPixelColor(0, 255, 255, 0);
  strip.show(); // Initialize LEDs

#if RST_PIN >= 0
  oled.begin(&Adafruit128x64, DISPLAY_I2C_ADDRESS, RST_PIN);
#else // RST_PIN >= 0
  oled.begin(&Adafruit128x64, DISPLAY_I2C_ADDRESS);
#endif // RST_PIN >= 0

  oled.setFont(System5x7);
  oled.clear();
  oled.println("Initializing...");

  pinMode(RELAY_PIN, OUTPUT); // Set up the relay

  receiver.enableIRIn(); // Start the receiver

  updateOutput();
}

void loop() {
  // put your main code here, to run repeatedly:
  delay(1); // this speeds up the simulation
  // Check if an IR signal has been received
  if (receiver.decode()) {
    toggleSwitch();
    receiver.resume();  // Receive the next value
  }
}

sketch.ino

diagram.json

# Wokwi Library List
# See https://docs.wokwi.com/guides/libraries

# Automatically added based on includes:
Adafruit NeoPixel

SSD1306Ascii
IRremote
