#include <WiFi.h>
#include <PubSubClient.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "mqtt.telkomiot.id";
const char* topic_pub = "v2.0/pubs/APP668502845056a37361/DEV66a74ef42890e25989";

String accessKey = "190760c7c967ea94";
String accessToken = "190760c7c966edcd";
String clientID = "DEV66a74ef42890e25989";

const int trigPin = 5;
const int echoPin = 18;

WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void setup() {
  Serial.begin(115200);
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "mqtt.telkomiot.id";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientID.c_str(), accessKey.c_str(), accessToken.c_str())) {
      Serial.println("Connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

long readUltrasonicDistance() {
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  long duration = pulseIn(echoPin, HIGH);
  long distance = (duration * 0.034) / 2; // Speed of sound wave divided by 2 (go and back)
  return distance;
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  static unsigned long lastMsg = 0;
  
  if (now - lastMsg > 2000) {
    lastMsg = now;

    long distance = readUltrasonicDistance();
    char msg[50];
    snprintf(msg, 50, "Distance: %ld cm", distance);
    Serial.print("Publish message: ");
    Serial.println(msg);
    client.publish(topic_pub, msg);
  }
}