#include <WiFi.h>
#include <ThingSpeak.h>
#include <Wire.h>
#include <Adafruit_Sensor.h>
#include <DHT.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET    -1
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define DHTPIN 27
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

const int soilMoisturePin = 34;
const int phSensorPin = 35;
const int ldrSensorPin = 32;

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const unsigned long channelID = 2613917; // Replace with your ThingSpeak channel ID
const char* writeAPIKey = "3DJGO1ZU3E6UCHU6";

WiFiClient client;

void setup() {
  Serial.begin(9600);
  Wire.begin(23, 22);
  
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;);
  }
  
  display.display();
  delay(2000);
  display.clearDisplay();
  
  dht.begin();
  
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi...");
  }
  Serial.println("Connected to WiFi");

  ThingSpeak.begin(client);
}

void loop() {
  int soilMoistureValue = analogRead(soilMoisturePin);
  float phValue = analogRead(phSensorPin) * (14.0 / 4095.0); // Adjust as necessary
  int ldrValue = analogRead(ldrSensorPin);
  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();

  if (isnan(temperature) || isnan(humidity)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0, 0);
  display.print("Soil Moisture: ");
  display.println(soilMoistureValue);
  display.print("Temperature: ");
  display.print(temperature);
  display.println(" C");
  display.print("Humidity: ");
  display.print(humidity);
  display.println(" %");
  display.print("pH Value: ");
  display.println(phValue);
  display.print("Light Level: ");
  display.println(ldrValue);
  display.display();

  ThingSpeak.setField(1, soilMoistureValue);
  ThingSpeak.setField(2, temperature);
  ThingSpeak.setField(3, humidity);
  ThingSpeak.setField(4, phValue);
  ThingSpeak.setField(5, ldrValue);

  int response = ThingSpeak.writeFields(channelID, writeAPIKey);
  if(response == 200) {
    Serial.println("Data sent to ThingSpeak successfully!");
  } else {
    Serial.println("Error sending data to ThingSpeak.");
  }

  delay(15000); // ThingSpeak rate limit is once every 15 seconds
}