#include <WiFi.h>
#include <WiFiClient.h>
#include <PubSubClient.h>

const float GAMMA = 0.7;
const float RL10 = 50.0;

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* hostname = "broker.hivemq.com";
WiFiClient espClient;
PubSubClient client(espClient);
const char* espClientName = "IOT/PROJECT";
int PORTNUM = 1883;

bool LEDState = LOW;
bool LEDOverride = false; 
unsigned long previousMillisMotion = 0;
unsigned long motionInterval = 3000; 

void setup_wifi() {
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.print(".");
  }
  Serial.println();
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

void connectMQTT() {
  while (!client.connected()) {
    Serial.println("Connecting to MQTT...");
    if (client.connect(espClientName)) {
      Serial.println("Connected");
      MQTTSubscribe();
    } else {
      Serial.print("Failed with state ");
      Serial.print(client.state());
      delay(2000);
    }
  }
}

void callback(char* topic, byte* payload, unsigned int length) {
  String messageTemp;

  for (int i = 0; i < length; i++) {
    messageTemp += (char)payload[i];
  }
  Serial.println();

  if (String(topic) == "IOT/PROJECT/control") {
    if (messageTemp == "ON") {
      LEDState = HIGH;
      LEDOverride = true;
      digitalWrite(18, LEDState);
      Serial.println("Light turned ON via MQTT PANEL");
    } else if (messageTemp == "OFF") {
      LEDState = LOW;
      LEDOverride = true;
      digitalWrite(18, LEDState);
      Serial.println("Light turned OFF via MQTT PANEL");
    }
  }
}

void setup_MQTT() {
  client.setServer(hostname, PORTNUM);
  client.setCallback(callback);
}

void MQTTSubscribe() {
  client.subscribe("IOT/PROJECT/control");
}

int getLuxValue() {
  int analogValue = analogRead(33);
  analogValue = map(analogValue, 4095, 0, 1024, 0);
  float voltage = analogValue / 1024.0 * 5;
  float resistance = 2000 * voltage / (1 - voltage / 5);
  int lux = pow(RL10 * 1e3 * pow(10, GAMMA) / resistance, (1 / GAMMA));
  return lux;
}

void publishMQTT(const char* topic, const char* message) {
  client.publish(topic, message);
}

void setup() {
  Serial.begin(115200);
  pinMode(13, INPUT); // Motion sensor pin
  pinMode(33, INPUT); // Light sensor pin
  pinMode(18, OUTPUT); // Light control pin

  setup_wifi();
  setup_MQTT();
}

void loop() {
  if (!client.connected()) {
    connectMQTT();
  }
  client.loop();

  unsigned long currentMillis = millis();

  if (currentMillis - previousMillisMotion >= motionInterval) {
    previousMillisMotion = currentMillis;
    int motionDetected = digitalRead(13);
    int lux = getLuxValue();
    Serial.print("Lux: ");
    Serial.println(lux);

    if (motionDetected == HIGH) {
      Serial.println("Motion Detected");
      if (!LEDOverride) {
        if (lux < 512) {
          LEDState = HIGH;
          Serial.println("Night time, Light turned ON");
        } else {
          LEDState = LOW;
          Serial.println("Day time, Light turned OFF");
        }
      }
    } else {
      Serial.println("No Motion Detected");
    }
    
    digitalWrite(18, LEDState);
  }
}