#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <DHTesp.h>

#define PIN_TRIG 5
#define PIN_ECHO 18
#define ON_LED 0
#define ALERT_LED 17
#define TANK_HEIGHT_CM 300  
#define BUZZER_ALARM 23
#define BUZZER_DURATION_MS 1000

LiquidCrystal_I2C lcd(0x27, 16, 2);

const int DHT_PIN = 33;

DHTesp dhtSensor;

unsigned long buzzerStartTime = 0; // store the time when the buzzer was turned on
bool buzzerActive = false; // track the buzzer state
bool warningOrNormalDetected = false; // track if warning or normal level was detected

unsigned long previousMillis = 0; // stores the last time LED was updated
const long interval = 500; // interval at which to blink (in milliseconds)
bool ledState = LOW; // current state of the LED

void setup() {
  Serial.begin(115200); // Baud rate of ESP32

  pinMode(PIN_TRIG, OUTPUT);
  pinMode(PIN_ECHO, INPUT);
  pinMode(ON_LED, OUTPUT);
  pinMode(ALERT_LED, OUTPUT);
  pinMode(BUZZER_ALARM, OUTPUT);

  digitalWrite(ON_LED, HIGH);
  digitalWrite(ALERT_LED, LOW);
  digitalWrite(BUZZER_ALARM, LOW);

  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);

  lcd.init(); 
  lcd.backlight(); 

  displayMsg("SystemInitialize", "Plase wait...");
  displayMsg("Water Level", "Monitoring");
}

void displayMsg(String message1, String message2) {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print(message1);
  lcd.setCursor(0, 1);
  lcd.print(message2);
  delay(3000);
}

int measureWaterLvl() {
  digitalWrite(PIN_TRIG, LOW);
  delayMicroseconds(2);
  digitalWrite(PIN_TRIG, HIGH);
  delayMicroseconds(10);
  digitalWrite(PIN_TRIG, LOW);

  int duration = pulseIn(PIN_ECHO, HIGH);
  Serial.print("Duration: "); 
  Serial.println(duration);   
  return duration * 0.0343 / 2; // convert duration to distance (cm)
}

int calcWaterLevel(int distanceCM) {
  return distanceCM; // delete this part
  // return TANK_HEIGHT_CM - distanceCM; // use this for water level measurement 
}


void handleWarningLevel() {
  unsigned long currentMillis = millis(); 
  if (currentMillis - previousMillis >= interval) {
    previousMillis = currentMillis; 
    ledState = !ledState; // toggle LED state
    digitalWrite(ALERT_LED, ledState); // update LED state
  }
  
  digitalWrite(BUZZER_ALARM, LOW); 
  noTone(BUZZER_ALARM); 
  buzzerActive = false; 
  warningOrNormalDetected = true; // set warning/normal detection flag
}

void handleCriticalLevel() {
  digitalWrite(ALERT_LED, HIGH); 
  if (!buzzerActive && warningOrNormalDetected) {
    digitalWrite(BUZZER_ALARM, HIGH);
    tone(BUZZER_ALARM, 1000);
    buzzerStartTime = millis();
    buzzerActive = true; 
    warningOrNormalDetected = false; // reset warning/normal detection flag
  }
}

void handleNormalLevel() {
  digitalWrite(ALERT_LED, LOW); 
  digitalWrite(BUZZER_ALARM, LOW);
  noTone(BUZZER_ALARM); 
  buzzerActive = false;
  warningOrNormalDetected = true; 
}

void checkBuzzer() {
  if (buzzerActive && (millis() - buzzerStartTime >= BUZZER_DURATION_MS)) {
    noTone(BUZZER_ALARM); // turn off the Buzzer
    buzzerActive = false; 
  }
}

String waterLvlStatus(int waterLevel) {
  if (waterLevel <= 50) { 
    return "CRITICAL";
  } else if (waterLevel <= 150) {
    return "WARNING";
  } else {
    return "NORMAL";
  }
}

String tempStatus(float temperature) {
  if (temperature < 5.0 || temperature > 45.0) {
    return "WARNING";
  } else {
    return "NORMAL";
  }
}
 
String humStatus(float humidity) {
  if (humidity < 20.0 || humidity > 80.0) {
    return "WARNING";
  } else {
    return "NORMAL";
  }
}

void displayLCD(int waterLevel, float temperature, float humidity) {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("WaterLvl: ");
  lcd.print(waterLevel);
  lcd.print("cm");
  lcd.setCursor(0, 1);
  lcd.print("Status: ");
  lcd.print(waterLvlStatus(waterLevel));
  delay(1500); 

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Temp: ");
  lcd.print(temperature, 1);
  lcd.print("degC");
  lcd.setCursor(0, 1);
  lcd.print("Status: ");
  lcd.print(tempStatus(temperature));
  delay(1500); 

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Hum: ");
  lcd.print(humidity, 1);
  lcd.print(" %RH");
  lcd.setCursor(0, 1);
  lcd.print("Status: ");
  lcd.print(humStatus(humidity));
  delay(1500); 
}

void loop() {
  int distanceCM = measureWaterLvl();
  int waterLevel = calcWaterLevel(distanceCM);

  // read temp and hum
  TempAndHumidity data = dhtSensor.getTempAndHumidity();
  float temperature = data.temperature;
  float humidity = data.humidity;

  displayLCD(waterLevel, temperature, humidity);

  // handle alarm and LED
  if (waterLevel <= 50) {
    handleCriticalLevel();
  } else if (waterLevel <= 150) { 
    handleWarningLevel();
  } else { 
    handleNormalLevel();
  }

  checkBuzzer();

  delay(100);
}