//Bibliotecas----------------------------------------------------------
#include <OneWire.h>
#include <DallasTemperature.h>
#include <LiquidCrystal_I2C.h>
#include <WiFi.h>
#include <ThingSpeak.h>
//Constantes e variáveis-----------------------------------------------
// GPIO onde o DS18B20 está conectado
const int OneWireBus = 4;
// Configure uma instância oneWire para se comunicar com qualquer dispositivo OneWire
OneWire oneWire(OneWireBus);
// Passe nossa referência oneWire para o sensor de temperatura Dallas
DallasTemperature sensors(&oneWire);
// Config. o endereço I2C LCD para 0x27 com 16 caracteres e 2 linhas
LiquidCrystal_I2C lcd(0x27,16,2);
//Credenciais WiFi
char ssid[] = "Wokwi-GUEST"; // Rede WiFi - SSID (nome)
char pass[] = ""; // Senha da rede WiFi
WiFiClient client;
//Dados de acesso ao canal do ThingSpeak
unsigned long myChannelNumber = 2627020; //ThingSpeak Channel ID
const char * myWriteAPIKey = "DDH4U8W6HPXSRP2W"; //ThingSpeak Channel Write API Key
void setup() {
// Inicia o Serial Monitor
Serial.begin(115200);
// Inicia o DS18B20 sensor
sensors.begin();
//Inicia o lcd
lcd.init();
//Ativa o backlight do lcd
lcd.backlight();

// Conectar ao WiFi
WiFi.begin(ssid, pass);
Serial.print("Conectando-se a rede WiFi: ");
Serial.println(ssid);
while(WiFi.status() != WL_CONNECTED){
Serial.print(".");
delay(5000);
}
Serial.println("");
Serial.println("WiFi conectado!");
Serial.print("Endereço IP: ");
Serial.println(WiFi.localIP()); //Exibe o endereço IP
ThingSpeak.begin(client); // Inicializa o ThingSpeak
}
void loop() {
//Faz a leitura de temperatura
sensors.requestTemperatures();
//Armazena os valores medidos em celsius e em fahrenheit
float temperaturaC = sensors.getTempCByIndex(0);
float temperaturaF = sensors.getTempFByIndex(0);
//Exibe a temperatura no Serial Monitor
Serial.print(temperaturaC);
Serial.println("ºC");
Serial.print(temperaturaF);
Serial.println("ºF");
//Exibe a temperatura no LCD
lcd.clear();
lcd.setCursor(0,0);
lcd.print(temperaturaC);
lcd.print(" C");
lcd.setCursor(0,1);
lcd.print(temperaturaF);
lcd.print(" F");
// Envia e grava os dados no ThingSpeak.

// Há 8 fields no canal, e é possível armazenar 8 diferentes dados
// em um canal. Aqui gravaremos no field 1.
// Enviaremos a temperatura em Celsius
int x = ThingSpeak.writeField(myChannelNumber, 1, temperaturaC,
myWriteAPIKey);
//ThingSpeak.writeField irá retornar um código HTTP,
//se for 200, os dados foram enviados com sucesso.
if(x == 200){
Serial.println("Canal atualizado com sucesso!");
}
else{
Serial.println("Problema ao atualizar o canal. Código de erro HTTP: " +
String(x));
}
delay(20000); // Aguarda 20 segundos para atualizar o canal(versão gratuita limita 15 seg)
}