#include <Arduino.h>
#include <WiFi.h> 
#include <PubSubClient.h>
#include <DHTesp.h>

#define SOIL_MOISTURE_PIN 35  // Pin connected to the soil moisture sensor
#define LDR_PIN 34            // Pin connected to the LDR
#define LIGHT_PIN  2          // Pin connected to the first LED or relay
#define PUMP_PIN  4           // Pin connected to the second LED
#define FAN_PIN  5            // Pin connected to the third LED
#define CURTAIN_PIN 18        // Pin connected to the curtain motor


const int DHT_PIN = 21; 
DHTesp dht;
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "test.mosquitto.org";


WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;
float temp = 0;
float hum = 0;
int soilMoisture = 0;
int ldrValue = 0;

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  String message;
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
    message += (char)payload[i];
  }
  Serial.println();

  if (String(topic) == "/ThinkIOT/Light") {
    if (message == "true") {
      digitalWrite(LIGHT_PIN, HIGH);
    } else if (message == "false") {
      digitalWrite(LIGHT_PIN, LOW);
    }
  } else if (String(topic) == "/ThinkIOT/Pump") {
    if (message == "true") {
      digitalWrite(PUMP_PIN, HIGH);
    } else if (message == "false") {
      digitalWrite(PUMP_PIN, LOW);
    }
  } else if (String(topic) == "/ThinkIOT/Fan") {
    if (message == "true") {
      digitalWrite(FAN_PIN, HIGH);
    } else if (message == "false") {
      digitalWrite(FAN_PIN, LOW);
    }
  } else if (String(topic) == "/ThinkIOT/Curtain") {
    if (message == "true") {
      digitalWrite(CURTAIN_PIN, HIGH);
    } else if (message == "false") {
      digitalWrite(CURTAIN_PIN, LOW);
    }
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("Connected");
      client.publish("/ThinkIOT/Publish", "Welcome");
      client.subscribe("/ThinkIOT/Subscribe");
      client.subscribe("/ThinkIOT/Light");
      client.subscribe("/ThinkIOT/Pump");
      client.subscribe("/ThinkIOT/Fan");
      client.subscribe("/ThinkIOT/Curtain");
     
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  pinMode(SOIL_MOISTURE_PIN, INPUT);
  pinMode(LDR_PIN, INPUT);
  pinMode(LIGHT_PIN, OUTPUT);
  pinMode(PUMP_PIN, OUTPUT);
  pinMode(FAN_PIN, OUTPUT);
  pinMode(CURTAIN_PIN, OUTPUT);
 
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  dht.setup(DHT_PIN, DHTesp::DHT11);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;
    TempAndHumidity data = dht.getTempAndHumidity();

    String temp = String(data.temperature, 2);
    client.publish("/ThinkIOT/temp", temp.c_str());
    String hum = String(data.humidity, 1);
    client.publish("/ThinkIOT/hum", hum.c_str());

    soilMoisture = analogRead(SOIL_MOISTURE_PIN);
    String soilMoistureStr = String(soilMoisture);
    client.publish("/ThinkIOT/soil", soilMoistureStr.c_str());

    ldrValue = analogRead(LDR_PIN);
    String ldrValueStr = String(ldrValue);
    client.publish("/ThinkIOT/ldr",ldrValueStr.c_str());

    Serial.print("Temperature: ");
    Serial.println(temp);
    Serial.print("Humidity: ");
    Serial.println(hum);
    Serial.print("Soil Moisture: ");
    Serial.println(soilMoistureStr);
    Serial.print("LDR Value: ");
    Serial.println(ldrValueStr);
  }
}