# Welcome to The Bin! 🦝

Now that you've thrown some parts into The Bin, it's time to turn that trash into treasure! 🗑️➡️💎

Wire up your parts and write some code to make them work together. If you need
help with a part, click the "?" above it.

If you want to see examples, check here:
https://hack.club/bin-example

You can get help by chatting with other high schoolers on the Hack Club Slack in
the #electronics channel:
👉 https://hackclub.com/slack 👈

Once you're ready build your design IRL, click the "Share" button and submit
your design:
https://hack.club/bin-submit
    

help.md

#include <Wire.h>
#include <SSD1306Ascii.h>
#include <SSD1306AsciiWire.h>
#include <Adafruit_NeoPixel.h>
#include "keypad.h"
#include "bargraph.h"

// Bar graph
#define BAR_GRAPH_DATA_PIN 15
#define BAR_GRAPH_CLOCK_PIN 18
#define BAR_GRAPH_LATCH_PIN 14
#define BAR_GRAPH_LED_PIN_8 16
#define BAR_GRAPH_LED_PIN_9 17

// OLED Display
#define OLED_I2C_ADDRESS 0x3C
#define OLED_RST_PIN -1

// Analog stick
#define ANALOG_STICK_VERTICAL A1
#define ANALOG_STICK_HORIZONTAL A2
#define ANALOG_STICK_CLICK 22
const int ANALOG_STICK_DEADZONE = 2;

// Fader
#define FADER_PIN A0

// Neopixel
#define NEOPIXEL_PIN 2
#define NEOPIXEL_COUNT 1

// Rotary Encoder configuration
#define ROTARY_ENCODER_CLK_PIN 7
#define ROTARY_ENCODER_DT_PIN 8
#define ROTARY_ENCODER_SW_PIN 9

// Keypad
#define KEYPAD_PIN_R1 21
#define KEYPAD_PIN_R2 20
#define KEYPAD_PIN_R3 3
#define KEYPAD_PIN_R4 6
#define KEYPAD_PIN_C1 10
#define KEYPAD_PIN_C2 11
#define KEYPAD_PIN_C3 12
#define KEYPAD_PIN_C4 13

// Create an object for the bar graph
Bargraph bargraph(BAR_GRAPH_DATA_PIN, BAR_GRAPH_CLOCK_PIN, BAR_GRAPH_LATCH_PIN, BAR_GRAPH_LED_PIN_8, BAR_GRAPH_LED_PIN_9);

// Create an object for the OLED
SSD1306AsciiWire oled;

// Create an object for the keypad
#define KEYPAD_ROWS 4
#define KEYPAD_COLS 4
byte keypadRowPins[KEYPAD_ROWS] = {KEYPAD_PIN_R1, KEYPAD_PIN_R2, KEYPAD_PIN_R3, KEYPAD_PIN_R4};
byte keypadColPins[KEYPAD_COLS] = {KEYPAD_PIN_C1, KEYPAD_PIN_C2, KEYPAD_PIN_C3, KEYPAD_PIN_C4};
Keypad keypad = Keypad(keypadRowPins, keypadColPins, KEYPAD_ROWS, KEYPAD_COLS);

// Create an object for the NeoPixel
Adafruit_NeoPixel strip(NEOPIXEL_COUNT, NEOPIXEL_PIN, NEO_GRB + NEO_KHZ800);

// Store the states of things
int faderPosition;
int lastFaderPosition;
byte preview = 0;
byte program = 1;
bool previewProgram = false;
int analogStickX;
int analogStickY;

void updateDisplay() {
  oled.clear();
  oled.print("Preview: ");
  oled.println(preview);
  oled.print("Program: ");
  oled.println(program);
}

void updateLED() {
  if (previewProgram) {
    strip.setPixelColor(0, 255, 0, 0);
  } else {
    strip.setPixelColor(0, 0, 255, 0);
  }
  strip.show(); // Initialize LEDs
}

void updateAnalogStick() {
  analogStickX = analogRead(ANALOG_STICK_HORIZONTAL) - 512;
  analogStickY = analogRead(ANALOG_STICK_VERTICAL) - 512;
}

void setPreview(byte newPreview) {
  preview = newPreview;
  Serial1.print("preview ");
  Serial1.println(preview);
  updateDisplay();
}

void setup() {
  // put your setup code here, to run once:
  Serial1.begin(115200);
  Serial1.println("Hello, Raspberry Pi Pico W!");

  // Set up I2C
  Wire.begin();
  Wire.setClock(400000L);

  // Set up the OLED
#if OLED_RST_PIN >= 0
  oled.begin(&Adafruit128x64, OLED_I2C_ADDRESS, RST_PIN);
#else
  oled.begin(&Adafruit128x64, OLED_I2C_ADDRESS);
#endif

  bargraph.write(0);

  strip.begin();
  strip.setPixelColor(0, 255, 255, 0);
  strip.show(); // Initialize LEDs

  pinMode(ROTARY_ENCODER_DT_PIN, INPUT);
  pinMode(ROTARY_ENCODER_CLK_PIN, INPUT);
  
  attachInterrupt(ROTARY_ENCODER_CLK_PIN, updateEncoder, FALLING);

  oled.setFont(System5x7);
  updateDisplay();
  updateLED();
}

void loop() {
  // put your main code here, to run repeatedly:
  delay(10); // this speeds up the simulation

  int key = keypad.read();
  if (key != 100) {
    switch(key) {
      case 00:
        setPreview(0);
        break;
      case 01:
        setPreview(1);
        break;
      case 02:
        setPreview(2);
        break;
      case 10:
        setPreview(3);
        break;
    }
  }

  faderPosition = analogRead(FADER_PIN);
  if (lastFaderPosition != faderPosition) {
    Serial1.print("fade ");
    Serial1.println(faderPosition);
    bargraph.write(map(faderPosition, 0, 1023, 0, 10));
    lastFaderPosition = faderPosition;
    if (faderPosition == 0 || faderPosition == 1023) {
      previewProgram = !previewProgram;
      int lastPreview = preview;
      preview = program;
      program = lastPreview;
      updateLED();
      updateDisplay();
    }
  }

  updateAnalogStick();
  if (analogStickY > ANALOG_STICK_DEADZONE || analogStickY < -ANALOG_STICK_DEADZONE) {
    Serial1.print("zoom ");
    Serial1.println(analogStickY);
  }
}

void updateEncoder() {
  if (digitalRead(ROTARY_ENCODER_DT_PIN) == HIGH) {
    Serial1.println("focus push");
  } else{
    Serial1.println("focus pull");
  }
}

sketch.ino

diagram.json

#ifndef BARGRAPH_H
#define BARGRAPH_H

#include <Arduino.h>

class Bargraph {
  private:
    byte dataPin; // DS
    byte clockPin; // SHCP
    byte latchPin; // STCP
    byte ledPin8;
    byte ledPin9;
    int pattern;
    
  public:
    // Setup bar graph and call init()
    Bargraph(byte dataPin, byte clockPin, byte latchPin, byte ledPin8, byte ledPin9);

    // Setup the bargraph
    void init();
    
    // Set a value to the bargraph
    void write(byte value);
};

#endif

bargraph.h

#include "bargraph.h"

Bargraph::Bargraph(byte dataPin, byte clockPin, byte latchPin, byte ledPin8, byte ledPin9) {
  this->clockPin = clockPin;
  this->dataPin = dataPin;
  this->latchPin = latchPin;
  this->ledPin8 = ledPin8;
  this->ledPin9 = ledPin9;
  init();
}

void Bargraph::init() {
  pinMode(dataPin, OUTPUT);
  pinMode(clockPin, OUTPUT);
  pinMode(latchPin, OUTPUT);
  pinMode(ledPin8, OUTPUT);
  pinMode(ledPin9, OUTPUT);
  this->pattern = 0b0000000000;
}

void Bargraph::write(byte value) {
  // Loop through the possible outputs on the shift register, and set the bits depending on whether that output should be on or not
  for (int i = 0; i <= 9; i++) {
    bitWrite(pattern, i, i <= (value - 1));
  }

  // Write the pattern to the shift register
  digitalWrite(latchPin, LOW);
  shiftOut(dataPin, clockPin, MSBFIRST, pattern);
  digitalWrite(latchPin, HIGH);

  // Set the LEDs that are not connected to the shift register
  digitalWrite(ledPin8, bitRead(pattern, 8));
  digitalWrite(ledPin9, bitRead(pattern, 9));
}

bargraph.cpp

# Wokwi Library List
# See https://docs.wokwi.com/guides/libraries

# Automatically added based on includes:
SSD1306Ascii
Adafruit NeoPixel


libraries.txt

#ifndef KEYPAD_H
#define KEYPAD_H

#include <Arduino.h>

class Keypad {
  private:
    byte* rowPins;
    byte* colPins;
    byte rows;
    byte cols;
    
  public:
    // Setup keypad and call init()
    Keypad(byte* rowPins, byte* colPins, byte rows, byte cols);

    // Setup the keypad
    void init();
    
    // Get the pressed key
    int read();
};

#endif

keypad.h

#include "keypad.h"

Keypad::Keypad(byte* rowPins, byte* colPins, byte rows, byte cols) {
  this->rowPins = rowPins;
  this->colPins = colPins;
  this->rows = rows;
  this->cols = cols;
  init();
}

void Keypad::init() {
  for (int i=0; i < rows; i++) {
    pinMode(rowPins[i], OUTPUT);
    digitalWrite(rowPins[i], HIGH);
  }
  for (int i=0; i < cols; i++) {
    pinMode(colPins[i], INPUT_PULLUP);
  }
}

int Keypad::read() {
  // Iterate through rows, write a LOW to each, and check if any columns are active
  for (int i = 0; i < rows; i++) {
    digitalWrite(rowPins[i], LOW);

    // Iterate through columns and read each of them
    for (int j = 0; j < cols; j++) {
      // If a key is pressed, return its coordinates
      if (digitalRead(colPins[j]) == LOW) {
        digitalWrite(rowPins[i], HIGH);
        return j + (i * 10);
      }
    }

    // Reset the row so the next one can be read
    digitalWrite(rowPins[i], HIGH);
  }

  return 100;
}