#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <DHTesp.h>

#define PIN_TRIG 5
#define PIN_ECHO 18
#define ON_LED 0
#define ALERT_LED 17
#define TANK_HEIGHT_CM 300  
#define BUZZER_ALARM 23
#define BUZZER_DURATION_MS 5000 
#define NEXT_BUTTON 13
#define PREV_BUTTON 14
#define DHT_22 33

LiquidCrystal_I2C lcd(0x27, 16, 2);

int num = 1; // start with water lvl (num 1)

DHTesp dhtSensor;

unsigned long buzzerStartTime = 0; 
bool buzzerActive = false; 
bool warningOrNormalDetected = false; 
unsigned long previousMillis = 0; 
const long interval = 500; 
bool ledState = LOW; 

void setup() {
  Serial.begin(115200); 

  pinMode(PIN_TRIG, OUTPUT);
  pinMode(PIN_ECHO, INPUT);
  pinMode(ON_LED, OUTPUT);
  pinMode(ALERT_LED, OUTPUT);
  pinMode(BUZZER_ALARM, OUTPUT);

  pinMode(NEXT_BUTTON, INPUT_PULLUP);
  pinMode(PREV_BUTTON, INPUT_PULLUP);

  digitalWrite(ON_LED, HIGH);
  digitalWrite(ALERT_LED, LOW);
  digitalWrite(BUZZER_ALARM, LOW);

  dhtSensor.setup(DHT_22, DHTesp::DHT22);

  lcd.init(); 
  lcd.backlight(); 

  displayMsg("System Initialize", "Please wait...");
}

void displayMsg(String message1, String message2) {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print(message1);
  lcd.setCursor(0, 1);
  lcd.print(message2);
  delay(3000);
}

int measureWaterLvl() {
  digitalWrite(PIN_TRIG, LOW);
  delayMicroseconds(2);
  digitalWrite(PIN_TRIG, HIGH);
  delayMicroseconds(10);
  digitalWrite(PIN_TRIG, LOW);

  int duration = pulseIn(PIN_ECHO, HIGH);
  return duration * 0.0343 / 2; 
}

int calcWaterLevel(int distanceCM) {
  return distanceCM; 
}

void handleWarningLevel() {
  unsigned long currentMillis = millis(); 
  if (currentMillis - previousMillis >= interval) {
    previousMillis = currentMillis; 
    ledState = !ledState; 
    digitalWrite(ALERT_LED, ledState); 
  }
  
  digitalWrite(BUZZER_ALARM, LOW); 
  noTone(BUZZER_ALARM); 
  buzzerActive = false; 
  warningOrNormalDetected = true; 
}

void handleCriticalLevel() {
  digitalWrite(ALERT_LED, HIGH); 
  if (!buzzerActive && warningOrNormalDetected) {
    digitalWrite(BUZZER_ALARM, HIGH);
    tone(BUZZER_ALARM, 1000);
    buzzerStartTime = millis();
    buzzerActive = true; 
    warningOrNormalDetected = false; 
  }
}

void handleNormalLevel() {
  digitalWrite(ALERT_LED, LOW); 
  digitalWrite(BUZZER_ALARM, LOW);
  noTone(BUZZER_ALARM); 
  buzzerActive = false;
  warningOrNormalDetected = true; 
}

void checkBuzzer() {
  if (buzzerActive && (millis() - buzzerStartTime >= BUZZER_DURATION_MS)) {
    noTone(BUZZER_ALARM); 
    buzzerActive = false; 
  }
}

String waterLvlStatus(int waterLevel) {
  if (waterLevel <= 50) { 
    return "CRITICAL";
  } else if (waterLevel <= 150) {
    return "WARNING";
  } else {
    return "NORMAL";
  }
}

String tempStatus(float temperature) {
  if (temperature < 5.0 || temperature > 45.0) {
    return "WARNING";
  } else {
    return "NORMAL";
  }
}

String humStatus(float humidity) {
  if (humidity < 20.0 || humidity > 80.0) {
    return "WARNING";
  } else {
    return "NORMAL";
  }
}

void displayWaterLevel(int waterLevel) {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("WaterLvl: ");
  lcd.print(waterLevel);
  lcd.print(" cm");
  lcd.setCursor(0, 1);
  lcd.print("Status: ");
  lcd.print(waterLvlStatus(waterLevel));
}

void displayTemperature(float temperature) {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Temp: ");
  lcd.print(temperature, 1);
  lcd.print(" degC");
  lcd.setCursor(0, 1);
  lcd.print("Status: ");
  lcd.print(tempStatus(temperature));
}

void displayHumidity(float humidity) {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Hum: ");
  lcd.print(humidity, 1);
  lcd.print(" %RH");
  lcd.setCursor(0, 1);
  lcd.print("Status: ");
  lcd.print(humStatus(humidity));
}

void loop() {
  int valNext = digitalRead(NEXT_BUTTON); 
  int valPrev = digitalRead(PREV_BUTTON); 

  Serial.print("Next Button State: ");
  Serial.print(valNext);
  Serial.print(" | Prev Button State: ");
  Serial.println(valPrev);

  // num increment if NEXT_BUTTON is pressed
  // INPUT_PULLUP >> when pressed, valnext = LOW
  if (valNext == LOW) { 
    num++;
    if (num > 3) num = 1; 
    delay(50); // debounce delay
  }
  
  // num decrement if PREV_BUTTON is pressed
  if (valPrev == LOW) { 
    num--;
    if (num < 1) num = 3; 
    delay(50);
  }

  int distanceCM = measureWaterLvl();
  int waterLevel = calcWaterLevel(distanceCM);
  TempAndHumidity data = dhtSensor.getTempAndHumidity();
  float temperature = data.temperature;
  float humidity = data.humidity;

// display based on current num
  switch (num) {
    case 1:
      displayWaterLevel(waterLevel);
      break;
    case 2:
      displayTemperature(temperature);
      break;
    case 3:
      displayHumidity(humidity);
      break;
  }

  // sensor alerts
  if (waterLevel <= 50) {
    handleCriticalLevel();
  } else if (waterLevel <= 150) { 
    handleWarningLevel();
  } else { 
    handleNormalLevel();
  }

  checkBuzzer();
  delay(1000); // main loop delay
}