#include <TinyGPS++.h>
#include <WiFi.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>


#define GPS_BAUDRATE 9600      // The default baudrate of NEO-6M is 9600
#define RX_PIN 16              // RX pin for GPS UART
#define TX_PIN 17              // TX pin for GPS UART


// WiFi and Ubidots configuration
const char* ssid = "Wokwi-GUEST";  // Wokwi's default SSID
const char* password = "";         // No password needed for Wokwi-GUEST
const char* mqtt_server = "industrial.api.ubidots.com";
const char* token = "BBUS-uyyEgtT5mAapX0nYxUZrIcgB7moX1D";  // Replace with your Ubidots Token
const char* device_label = "gps_main";
const char* topic = "/v1.6/devices/gps_main";


// Global objects
TinyGPSPlus gps;
WiFiClient espClient;
PubSubClient client(espClient);


void setup_wifi() {
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}


void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect("ESP32Client", token, "")) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}


void setup() {
  Serial.begin(9600);
  Serial2.begin(GPS_BAUDRATE, SERIAL_8N1, RX_PIN, TX_PIN);


  // Connect to WiFi and MQTT
  setup_wifi();
  client.setServer(mqtt_server, 1883);
}


void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();


  if (Serial2.available() > 0) {
    if (gps.encode(Serial2.read())) {
      DynamicJsonDocument jsonDoc(1024);
     
      if (gps.location.isValid()) {
        float latitude = gps.location.lat();
        float longitude = gps.location.lng();
        float altitude = gps.altitude.isValid() ? gps.altitude.meters() : 0;
        float speed = gps.speed.isValid() ? gps.speed.kmph() : 0;
       
        // Send data to Ubidots
        jsonDoc["latitude"] = latitude;
        jsonDoc["longitude"] = longitude;
        jsonDoc["altitude"] = altitude;
        jsonDoc["speed"] = speed;


        char buffer[512];
        serializeJson(jsonDoc, buffer);
        client.publish(topic, buffer);
      }
    }
  }


  if (millis() > 5000 && gps.charsProcessed() < 10) {
    Serial.println(F("No GPS data: check wiring"));
  }
}