//Bibliotecas---------------------------------------------------
#include <OneWire.h>
#include <DallasTemperature.h>
#include <LiquidCrystal_I2C.h>
#include <WiFi.h>
#include <PubSubClient.h>

//Constantes e variáveis----------------------------------------
// GPIO onde o DS18B20 está conectado
const int OneWireBus = 4;     

float temperaturaC, temperaturaF; 
// Configure uma instância oneWire para se comunicar com qualquer dispositivo OneWire
OneWire oneWire(OneWireBus);

// Passe nossa referência oneWire para o sensor de temperatura Dallas
DallasTemperature sensors(&oneWire);

// Config. o endereço I2C LCD para 0x27 com 16 caracteres e 2 linhas
LiquidCrystal_I2C lcd(0x27,16,2); 

//Config. SSID e Senha do WiFi
const char* ssid = "Wokwi-GUEST";
const char* password = "";

//Config. Servidor MQTT
const char* mqtt_server = "test.mosquitto.org";

//Cria um cliente que pode se conectar a um endereço IP e porta de internet especificados, 
//conforme definido em client.connect().
WiFiClient ClienteWokwi;
//Esta biblioteca permite que você envie e receba mensagens MQTT.
PubSubClient client(ClienteWokwi);

//Função que verifica se foi estabelecida conexão
void reconnect() {
  while (!client.connected()) {
    Serial.print("Estabelecendo conexao MQTT...");
    if (client.connect("ClienteWokwi")) {
      Serial.println("Conectado");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" tentando novamente em 5 segundos");
      // Aguardando 5 segundos
      delay(5000);
    }
  }
}
void publica_dados()
{
  client.publish("ESP32-MAP",String(temperaturaC).c_str());
  delay(1000);
}
void setup() {
  // Inicia o Serial Monitor
  Serial.begin(115200);
  // Inicia o DS18B20 sensor
  sensors.begin();
  //Inicia o lcd
  lcd.init();
  //Ativa o backlight do lcd
  lcd.backlight();
  Serial.print("Conectando... ");
  Serial.print(ssid);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password,6);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("WiFi connectado!");
  Serial.println("Endereco IP: ");
  Serial.println(WiFi.localIP());
  client.setServer(mqtt_server, 1883);
}

void loop() {
  //Faz a leitura de temperatura
  sensors.requestTemperatures();
  //Armazena os valores medidos em celsius e em fahrenheit
  temperaturaC = sensors.getTempCByIndex(0);
  temperaturaF = sensors.getTempFByIndex(0);
  //Exibe a temperatura no Serial Monitor
  Serial.print(temperaturaC);
  Serial.println("ºC");
  Serial.print(temperaturaF);
  Serial.println("ºF");
  //Exibe a temperatura no LCD
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print(temperaturaC);
  lcd.print((char) 223);
  lcd.print("C");
  lcd.setCursor(0,1);
  lcd.print(temperaturaF);
  lcd.print((char) 223);
  lcd.print("F");
  if (!client.connected()) {
    reconnect();
  }
  publica_dados();
  delay(5000);
}