#include <WiFi.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>  // Library untuk parsing JSON

#define ledg 2
#define ledy 4
#define ledr 5

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqtt_server = "mqttmuti.sija-bridge.tech";
const int mqtt_port = 1808;
const char* topicMQTT = "kinasih/device";

WiFiClient espClient;
PubSubClient clientMQTT(espClient);

void connectToInternet();
void setupMQTT();
void reconnectMQTT();

void setup() {
  pinMode(ledg, OUTPUT);
  pinMode(ledy, OUTPUT);
  pinMode(ledr, OUTPUT);
  
  Serial.begin(9600);
  connectToInternet();
  setupMQTT();
  clientMQTT.setCallback(callback);
}

void connectToInternet() {
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.print("IP Address: ");
  Serial.println(WiFi.localIP());
}

void setupMQTT() {
  clientMQTT.setServer(mqtt_server, mqtt_port);
}

void reconnectMQTT() {
  while (!clientMQTT.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    if (clientMQTT.connect(clientId.c_str())) {
      Serial.println("connected");
      clientMQTT.subscribe(topicMQTT);
    } else {
      Serial.print("failed, rc=");
      Serial.print(clientMQTT.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.print(topic);
  String messageTemp;
  for (int i = 0; i < length; i++) {
    messageTemp += (char)message[i];
  }
  Serial.println("Message: " + messageTemp);
  
  if (String(topic) == topicMQTT) {
    float distance = parseDistance(messageTemp);
    controlLEDs(distance);
  }
}

float parseDistance(String message) {
  StaticJsonDocument<200> doc;
  DeserializationError error = deserializeJson(doc, message);
  
  if (error) {
    Serial.print("Failed to parse JSON: ");
    Serial.println(error.c_str());
    return -1;
  }
  
  float distance = doc["distance"];
  return distance;
}

void controlLEDs(float distance) {
  if (distance < 20) {
    digitalWrite(ledy, HIGH);
    digitalWrite(ledr, LOW);
    digitalWrite(ledg, LOW);
    Serial.println("Warning: Distance below 20 cm");
  } else if (distance > 100) {
    digitalWrite(ledy, LOW);
    digitalWrite(ledr, HIGH);
    digitalWrite(ledg, LOW);
    Serial.println("Danger: Distance above 100 cm");
  } else {
    digitalWrite(ledy, LOW);
    digitalWrite(ledr, LOW);
    digitalWrite(ledg, HIGH);
    Serial.println("Normal: Distance between 20 cm and 100 cm");
  }
}

void loop() {
  if (!clientMQTT.connected()) {
    reconnectMQTT();
  }
  clientMQTT.loop();
}