#include <WiFi.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>
#include <DHT.h>

// Definisi WiFi
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Definisi MQTT
const char* mqttServer = "mqttthara.sija-bridge.tech";
const int mqttPort = 1831;
const char* mqttTopic = "thara/device";
const char* mqttControlTopic = "thara/device/control";

// Pin DHT22
#define DHTPIN 18  // Pin sensor DHT22
#define DHTTYPE DHT22

// LED pins
const int ledgreen = 2;
const int ledyellow = 4;
const int ledblue = 5;

// Variabel kontrol sensor
bool sensorEnabled = true;

DHT dht(DHTPIN, DHTTYPE);
WiFiClient wifiClient;
PubSubClient mqttClient(wifiClient);

void setup() {
  Serial.begin(9600);
  pinMode(ledgreen, OUTPUT);
  pinMode(ledyellow, OUTPUT);
  pinMode(ledblue, OUTPUT);
  
  connectToInternet();
  setupMQTT();
  
  dht.begin();
}

void connectToInternet() {
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("Connected to Wi-Fi");
  Serial.print("IP Address : ");
  Serial.println(WiFi.localIP());
}

void setupMQTT() {
  mqttClient.setServer(mqttServer, mqttPort);
  mqttClient.setCallback(callback);
}

void reconnectMQTT() {
  Serial.println("Connecting to MQTT Broker...");
  while (!mqttClient.connected()) {
    Serial.println("Attempting MQTT connection...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    
    if (mqttClient.connect(clientId.c_str())) {
      Serial.println("Connected to MQTT Broker.");
      mqttClient.subscribe(mqttControlTopic); // Subscribe to control topic
    } else {
      Serial.print("Failed, rc=");
      Serial.print(mqttClient.state());
      Serial.println(" Retrying in 5 seconds...");
      delay(5000);
    }     
  }
}

void callback(char* topic, byte* payload, unsigned int length) {
  String messageTemp;
  for (int i = 0; i < length; i++) {
    messageTemp += (char)payload[i];
  }

  Serial.print("Message received on topic: ");
  Serial.println(topic);
  Serial.print("Message: ");
  Serial.println(messageTemp);

  if (String(topic) == mqttControlTopic) {
    if (messageTemp == "ON") {
      sensorEnabled = true;
      Serial.println("Sensor enabled");
    } else if (messageTemp == "OFF") {
      sensorEnabled = false;
      Serial.println("Sensor disabled");
    }
  }
}

void controlLEDs(float temperature) {
  if (temperature < 20) {
    digitalWrite(ledyellow, HIGH);
    digitalWrite(ledblue, LOW);
    digitalWrite(ledgreen, LOW);
    Serial.println("Warning: Temperature below 20°C");
  } else if (temperature > 30) {
    digitalWrite(ledyellow, LOW);
    digitalWrite(ledblue, HIGH);
    digitalWrite(ledgreen, LOW);
    Serial.println("Danger: Temperature above 30°C");
  } else {
    digitalWrite(ledyellow, LOW);
    digitalWrite(ledblue, LOW);
    digitalWrite(ledgreen, HIGH);
    Serial.println("Normal: Temperature between 20°C and 30°C");
  }
}

void loop() {
  if (!mqttClient.connected()) {
    reconnectMQTT();
  }
  
  mqttClient.loop();  // Pastikan client MQTT selalu memproses pesan yang masuk
  
  if (sensorEnabled) {
    float temperature = dht.readTemperature();
    float humidity = dht.readHumidity();

    if (!isnan(temperature) && !isnan(humidity)) {
      controlLEDs(temperature);

      StaticJsonDocument<200> doc;
      doc["temperature"] = temperature;
      doc["humidity"] = humidity;

      char buffer[200];
      serializeJson(doc, buffer);

      mqttClient.publish(mqttTopic, buffer);

      Serial.print("Temperature: ");
      Serial.print(temperature);
      Serial.println(" °C");
      
      Serial.print("Humidity: ");
      Serial.print(humidity);
      Serial.println(" %");
    } else {
      Serial.println("Failed to read from DHT sensor!");
    }
  } else {
    Serial.println("Sensor is off");
  }

  delay(2000);
}