#include "DHT.h"
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <Servo.h>

// Pin Definitions
#define DHTPIN 2
#define DHTTYPE DHT22
#define RELAY_PIN 7
#define LED_PIN 13
#define UV_LED_PIN 8
#define LDR_PIN A0
#define TRIG_PIN 6
#define ECHO_PIN 5
#define SERVO_PIN 9
#define RED_PIN 3
#define GREEN_PIN 10
#define BLUE_PIN 11

// Initialize DHT sensor
DHT dht(DHTPIN, DHTTYPE);

// Initialize LCD
LiquidCrystal_I2C lcd(0x27, 20, 4);

// Initialize Servo
Servo myServo;

void setup() {
  // Set pin modes
  pinMode(RELAY_PIN, OUTPUT);
  pinMode(LED_PIN, OUTPUT);
  pinMode(UV_LED_PIN, OUTPUT);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(RED_PIN, OUTPUT);
  pinMode(GREEN_PIN, OUTPUT);
  pinMode(BLUE_PIN, OUTPUT);
  
  digitalWrite(RELAY_PIN, LOW);
  digitalWrite(LED_PIN, LOW);
  digitalWrite(UV_LED_PIN, LOW);

  lcd.begin(20, 4);
  lcd.backlight();
  dht.begin();

  // Initialize Servo
  myServo.attach(SERVO_PIN);

  // Start serial communication for debugging
  Serial.begin(9600);
}

void loop() {
  // Membaca data dari sensor DHT22
  float h = dht.readHumidity();
  float t = dht.readTemperature();

  // Membaca data dari LDR
  int lightLevel = analogRead(LDR_PIN);

  // Membaca data dari sensor ultrasonik
  long duration, distance;
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  duration = pulseIn(ECHO_PIN, HIGH);
  distance = duration * 0.034 / 2;

  // Menampilkan data di LCD
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Suhu: ");
  lcd.print(t);
  lcd.print(" C");

  lcd.setCursor(0, 1);
  lcd.print("Kelembaban: ");
  lcd.print(h);
  lcd.print(" %");

  lcd.setCursor(0, 2);
  lcd.print("Cahaya: ");
  lcd.print(lightLevel);

  lcd.setCursor(0, 3);
  lcd.print("Jarak: ");
  lcd.print(distance);
  lcd.print(" cm");

  // Kontrol penyemprot air
  if (t > 30 || h < 40) {
    digitalWrite(RELAY_PIN, HIGH); // Relay on
    lcd.setCursor(0, 3);
    lcd.print("Air: ON  ");
  } else {
    digitalWrite(RELAY_PIN, LOW);  // Relay off
    lcd.setCursor(0, 3);
    lcd.print("Air: OFF ");
  }

  // Kontrol sinar UV berdasarkan sensor cahaya
  if (lightLevel < 450) { // Nilai threshold dapat disesuaikan
    digitalWrite(UV_LED_PIN, HIGH); // UV LED on
    lcd.setCursor(12, 3);
    lcd.print("UV: ON ");
  } else {
    digitalWrite(UV_LED_PIN, LOW);  // UV LED off
    lcd.setCursor(12, 3);
    lcd.print("UV: OFF");
  }

  // Kontrol servo berdasarkan jarak
  if (distance < 100) {
    myServo.write(90);  // Open
  } else {
    myServo.write(0);   // Close
  }

  // Ubah warna RGB LED berdasarkan suhu dan kelembapan
  if (t > 30 && h < 40) {
    setColor(255, 0, 0);  // Red (Panas dan Kering)
  } else if (t < 20 && h > 70) {
    setColor(0, 0, 255);  // Blue (Dingin dan Lembab)
  } else {
    setColor(0, 255, 0);  // Green (Normal)
  }

  delay(2000); // wait 2 seconds before the next loop
}

// Fungsi untuk mengatur warna RGB LED
void setColor(int redValue, int greenValue, int blueValue) {
  analogWrite(RED_PIN, redValue);
  analogWrite(GREEN_PIN, greenValue);
  analogWrite(BLUE_PIN, blueValue);
}