#include <DHT.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

// Definições para o DHT11
#define DHTPIN 2         // Pino onde o DHT11 está conectado
#define DHTTYPE DHT22    // Tipo de sensor DHT (DHT22)
// #define DHTTYPE DHT11    // Tipo de sensor DHT (DHT11)
DHT dht(DHTPIN, DHTTYPE);

// Definições para o Relé
#define RELEPIN 7        // Pino onde o módulo relé está conectado

// Definições para o OLED
#define SCREEN_WIDTH 128 // Largura da tela OLED
#define SCREEN_HEIGHT 64 // Altura da tela OLED
#define OLED_RESET    -1 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// Definições para o gráfico de barras horizontais
#define MAX_BAR_WIDTH 100  // Largura máxima das barras horizontais
#define BAR_HEIGHT 10      // Altura das barras

void setup() {
  // Inicialização do Serial Monitor
  Serial.begin(9600);
  
  // Inicialização do DHT11
  dht.begin();
  
  // Configuração do pino do relé como saída
  pinMode(RELEPIN, OUTPUT);
  digitalWrite(RELEPIN, LOW); // Inicialmente desliga o relé
  
  // Inicialização do display OLED
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;);
  }
  
  display.display();
  delay(2000); // Pausa para a tela inicial do OLED
  display.clearDisplay();
}

void loop() {
  // Leitura da temperatura e umidade do DHT11
  float h = dht.readHumidity();
  float t = dht.readTemperature();
  
  // Verifica se as leituras são válidas
  if (isnan(h) || isnan(t)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    return;
  }
  
  // Controle do Relé baseado na temperatura
  if (t < 45) {
    digitalWrite(RELEPIN, HIGH);  // Liga o aquecedor (ativa o relé)
  } else if (t > 55) {
    digitalWrite(RELEPIN, LOW); // Desliga o aquecedor (desativa o relé)
  }

  // Exibição no Serial Monitor
  Serial.print(F("Humidity: "));
  Serial.print(h);
  Serial.print(F("%  Temperature: "));
  Serial.print(t);
  Serial.println(F("°C"));

  // Limpa a tela para a próxima exibição
  display.clearDisplay();

  // Desenha as barras horizontais no gráfico
  drawHorizontalBarGraph(t, h);

  // Exibição dos valores numéricos no display OLED
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0, 0);
  display.print("Temperatura: ");
  display.print(t);
  display.write(0xF7);
  display.println("C");
  
  display.setCursor(0, 30);
  display.print("Humidade: ");
  display.print(h);
  display.println(" %");

  display.setCursor(40,55);
  display.print("-=Zelak=-");

  display.display();
  
  // Intervalo entre leituras
  delay(2000);
}

// Função para desenhar o gráfico de barras horizontais
void drawHorizontalBarGraph(float temperature, float humidity) {
  // Converte temperatura para a largura da barra
  int tempBarWidth = map(temperature, 0, 100, 0, MAX_BAR_WIDTH);  // Mapeia temperatura (0 a 100°C) para a largura da barra (0 a 100 pixels)
  int humBarWidth = map(humidity, 0, 100, 0, MAX_BAR_WIDTH);      // Mapeia umidade (0 a 100%) para a largura da barra (0 a 100 pixels)

  // Desenha a barra de temperatura
  display.fillRect(20, 10, tempBarWidth, BAR_HEIGHT, WHITE);

  // Desenha a barra de umidade
  display.fillRect(20, 40, humBarWidth, BAR_HEIGHT, WHITE);

  // Opcional: Desenha os contornos das barras
  display.drawRect(20, 10, MAX_BAR_WIDTH, BAR_HEIGHT, WHITE); // Contorno da barra de temperatura
  display.drawRect(20, 40, MAX_BAR_WIDTH, BAR_HEIGHT, WHITE); // Contorno da barra de umidade
}