#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

// Khai báo chân LED
#define LED_XANH 12
#define LED_VANG 13
#define LED_DO 14

// Ngưỡng nhiệt độ và độ ẩm
#define TEMP_LOW 20
#define TEMP_HIGH 30
#define HUMID_LOW 30
#define HUMID_HIGH 70

// Chân cảm biến DHT và loại cảm biến
#define DHTPIN 15
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

// Khai báo màn hình OLED
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

// Khai báo thông tin MQTT
#define MQTT_CLIENT_ID "clientidweather"
#define MQTT_BROKER    "broker.mqttdashboard.com"
#define MQTT_TOPIC     "dht22oled"

// Thông tin mạng WiFi
const char* ssid = "Wokwi-GUEST";         // Thay bằng SSID của bạn
const char* password = ""; // Thay bằng mật khẩu WiFi của bạn

WiFiClient espClient;
PubSubClient client(espClient);

// Biến toàn cục để lưu trạng thái nhấp nháy của LED
bool ledRedBlinkState = false;
bool ledYellowBlinkState = false;

void setup() {
  // Khởi tạo Serial Monitor
  Serial.begin(115200);

  // Khởi tạo LED
  pinMode(LED_XANH, OUTPUT);
  pinMode(LED_VANG, OUTPUT);
  pinMode(LED_DO, OUTPUT);

  // Khởi tạo cảm biến DHT
  dht.begin();

  // Khởi tạo màn hình OLED
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("OLED không khởi tạo được"));
    while (true);
  }
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(WHITE);

  // Kết nối WiFi
  connectWiFi();

  // Kết nối MQTT
  client.setServer(MQTT_BROKER, 1883);
}

void loop() {
  // Đảm bảo kết nối MQTT
  if (!client.connected()) {
    reconnectMQTT();
  }
  client.loop();

  // Đọc nhiệt độ và độ ẩm từ cảm biến DHT
  float temp = dht.readTemperature();
  float humid = dht.readHumidity();

  // Kiểm tra đọc dữ liệu
  if (isnan(temp) || isnan(humid)) {
    Serial.println(F("Lỗi đọc cảm biến DHT!"));
    display.clearDisplay();
    display.setCursor(0, 0);
    display.println("Loi doc cam bien!");
    display.display();
    delay(1000);
    return;
  }

  // Hiển thị nhiệt độ và độ ẩm lên OLED
  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("Nhiet do: ");
  display.print(temp);
  display.println(" C");
  display.print("Do am: ");
  display.print(humid);
  display.println(" %");


  // Gửi dữ liệu lên MQTT
  sendToMQTT(temp, humid);

  display.display();
  delay(500);  // Đợi 0.5 giây để cập nhật trạng thái LED nhấp nháy
}

// Hàm kết nối WiFi
void connectWiFi() {
  Serial.print("Connecting to WiFi...");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" Connected!");
}

// Hàm kết nối lại MQTT
void reconnectMQTT() {
  while (!client.connected()) {
    Serial.print("Connecting to MQTT...");
    if (client.connect(MQTT_CLIENT_ID)) {
      Serial.println(" Connected!");
    } else {
      Serial.print(" failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

// Hàm gửi dữ liệu lên MQTT
void sendToMQTT(float temperature, float humidity) {
  String payload = "{\"temperature\":" + String(temperature) + ",\"humidity\":" + String(humidity) + "}";
  client.publish(MQTT_TOPIC, payload.c_str());
}