/**
   Arduino Calculator

   Copyright (C) 2020, Uri Shaked.
   Released under the MIT License.
*/

#include <LiquidCrystal.h> //mengendalikan Liquid Crystal Display
#include <Keypad.h> //menginputkan data berupa angka dan huruf 
#include <Servo.h> //mengontrol perangkat

/* Display */
LiquidCrystal lcd(12, 11, 10, 9, 8, 7); //menghubungkan lcd dengan konfigurasi pin yang digunakan

/* Keypad setup */
const byte KEYPAD_ROWS = 4; //untuk memasukkan data angka
const byte KEYPAD_COLS = 4; //mewakili jumlah kolom 
byte rowPins[KEYPAD_ROWS] = {5, 4, 3, 2}; //menyimpan nomor pin yang digunakan untuk menghubungkan baris-baris pada keypad
byte colPins[KEYPAD_COLS] = {A3, A2, A1, A0}; //menyimpan nomor pin yang digunakan untuk menghubungkan kolom-kolom pada keypad
char keys[KEYPAD_ROWS][KEYPAD_COLS] = { //untuk menyimpan layout dari tombol-tombol pada keypad
  {'1', '2', '3', '+'},
  {'4', '5', '6', '-'},
  {'7', '8', '9', '*'},
  {'.', '0', '=', '/'}
};

Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, KEYPAD_ROWS, KEYPAD_COLS); //menginisialisasi objek Keypad

uint64_t value = 0; //mendeklarasikan dan menginisialisasi variabel

void showSpalshScreen() { //menampilkan pesan awal pada layar LCD
  lcd.print("GoodArduinoCode"); //menunjukkan pesan selamat datang atau identifikasi aplikasi pada layar LCD
  lcd.setCursor(3, 1); //Mengatur posisi kursor pada layar LCD
  String message = "Calculator"; //menampilkan pesan atau untuk diproses lebih lanjut
  for (byte i = 0; i < message.length(); i++) {
    lcd.print(message[i]); //Menampilkan karakter ke-i
    delay(50); //Memberi jeda 50 milidetik antara penampilan setiap karakter
  }
  delay(500); // membaca pesan sebelum melanjutkan
}

void updateCursor() {
  if (millis() / 250 % 2 == 0 ) { //Mengembalikan waktu 
    lcd.cursor(); //Mengaktifkan kursor pada layar 
  } else { //untuk menangani kondisi
    lcd.noCursor(); // mengatur agar kursor tidak ditampilkan pada layar 
  }
}

void setup() { //menuliskan setingan pin
  Serial.begin(115200); // menentukan kecepatan dan penerimaan data 
  lcd.begin(16, 2); //untuk menggerakkan tulisan

  showSpalshScreen(); //untuk menampilkan pesan awal 
  lcd.clear(); // Membersihkan semua tampilan pada layar
  lcd.cursor(); //Mengaktifkan kursor pada layar

  lcd.setCursor(1, 0); //menampilkan teks dari posisi 
}

char operation = 0;
String memory = ""; //menyimpan nilai yang disimpan dalam memori kalkulator
String current = ""; //memasukkan angka atau operator.
uint64_t currentDecimal; //Menyimpan nilai desimal
bool decimalPoint = false; //untuk menghindari penambahan titik desimal 

double calculate(char operation, double left, double right) {
  switch (operation) {
    case '+': return left + right;
    case '-': return left - right;
    case '*': return left * right;
    case '/': return left / right;
  }
}

void processInput(char key) {
  if ('-' == key && current == "") {
    current = "-";
    lcd.print("-");
    return;
  }

  switch (key) {
    case '+':
    case '-':
    case '*':
    case '/':
      if (!operation) {
        memory = current;
        current = "";
      }
      operation = key;
      lcd.setCursor(0, 1);
      lcd.print(key);
      lcd.setCursor(current.length() + 1, 1);
      return;

    case '=':
      float leftNum = memory.toDouble();
      float rightNum = current.toDouble();
      memory = String(calculate(operation, leftNum, rightNum));
      current = "";
      lcd.clear();
      lcd.setCursor(1, 0);
      lcd.print(memory);
      lcd.setCursor(0, 1);
      lcd.print(operation);
      return;

  }

  if ('.' == key && current.indexOf('.') >= 0) {
    return;
  }

  if ('.' != key && current == "0") {
    current = String(key);
  } else if (key) {
    current += String(key);
  }

  lcd.print(key);
}

void loop() {
  updateCursor();

  char key = keypad.getKey();
  if (key) {
    processInput(key);
  }
}