#include <WiFi.h>
#include <MQTT.h>
#include <ESP32Servo.h>
#include <NusabotSimpleTimer.h>
#include "DHTesp.h"

WiFiClient net;
MQTTClient client;
Servo servo;
NusabotSimpleTimer timer;
DHTesp dhtSensor;

const char ssid[] = "Wokwi-GUEST";
const char pass[] = "";

//pin nomor GPIO
const int pinRed = 2;
const int pinGreen = 4;
const int pinBlue = 16;
const int pinled = 13;
const int pinservo = 18;
const int pinpot = 33;
const int pinDHT = 25;

int pot, oldpot = 0;

void setup() {
  pinMode(pinRed, OUTPUT);
  pinMode(pinGreen, OUTPUT);
  pinMode(pinBlue, OUTPUT);
  pinMode(pinled, OUTPUT);
  servo.attach(pinservo, 500, 2400);
  pinMode(pinpot, INPUT);
  dhtSensor.setup(pinDHT, DHTesp::DHT22);
  Serial.begin(9600);

  WiFi.begin(ssid, pass);
  client.begin("klasskita.cloud.shiftr.io", net);

  client.onMessage(subscribe);
  timer.setInterval(1000, publishpot);
  timer.setInterval(2000, publishDHT);
  
  connect();
}

void loop() {
  client.loop();
  timer.run();
  if(!client.connected()){
    connect();
  }
  delay(10);
}

void subscribe(String &topic, String &data){
  if(topic == "klasskita/led"){
    if(data == "nyala"){
      digitalWrite(pinled, 1);
    } else if(data == "mati"){
      digitalWrite(pinled, 0);
    }
  }

  if(topic == "klasskita/servo"){
    int posservo = data.toInt();
    servo.write(posservo);
    Serial.println(posservo);
  }
}

void publishpot(){
  pot = analogRead(pinpot);

  if (pot != oldpot){
    client.publish("klasskita/potentiometer", String(pot), false, 1);
    oldpot = pot;
  }
}

void publishDHT(){
  TempAndHumidity  data = dhtSensor.getTempAndHumidity();

  client.publish("klasskita/suhu", String(data.temperature, 2), true, 1);
  client.publish("klasskita/kelembaban", String(data.humidity, 1), true, 1);
}

void rgb(bool Red, bool Green, bool Blue){
  digitalWrite(pinRed, Red);
  digitalWrite(pinGreen, Green);
  digitalWrite(pinBlue, Blue);
}

void connect(){
rgb(1,0,0); // merah
  while(WiFi.status() != WL_CONNECTED){
    delay(500);
  }
  rgb(0,1,0); // hijau

  client.setWill("klasskita/espone/status", "offline", true, 1);
  while(!client.connect("mqttx_f32b1b35", "klasskita", "yfJFiqxJ9dgja0j9")){
    delay(500); 
  }
  rgb(0,0,1); // biru
  client.publish("klasskita/espone/status", "online", true, 1);
  client.subscribe("klasskita/#", 1); //subscribe menggunakan Qos 1
}