// Dispay on Node-red

#include <WiFi.h>                 // Include WiFi library for ESP32
#include <PubSubClient.h>         // Include PubSubClient for MQTT
#include <DHT.h>                  // Include DHT library for the sensor

// WiFi credentials
const char* ssid = "Wokwi-GUEST";         // Replace with your WiFi SSID
const char* password = ""; // Replace with your WiFi Password

// MQTT Broker (HiveMQ)
const char* mqtt_server = "broker.hivemq.com"; 
const char* mqtt_topic = "learnpracticaliot/dht22";   // MQTT topic where the data will be published

// DHT22 sensor setup
#define DHTPIN 12            // DHT22 data pin connected to GPIO 4 (can be changed)
#define DHTTYPE DHT22       // DHT 22 sensor type
DHT dht(DHTPIN, DHTTYPE);   // Initialize DHT sensor

WiFiClient espClient;
PubSubClient client(espClient); // MQTT client

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);  // Connect to the WiFi

  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect
    if (client.connect("ESP32Client")) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  dht.begin();               // Initialize DHT22 sensor
  setup_wifi();               // Connect to WiFi
  client.setServer(mqtt_server, 1883);  // Set HiveMQ broker address and port
}

void loop() {
  if (!client.connected()) {
    reconnect();               // Reconnect if the connection is lost
  }
  client.loop();

  // Reading temperature and humidity from DHT22 sensor
  float humidity = dht.readHumidity();
  float temperature = dht.readTemperature();

  // Check if any reads failed and exit early
  if (isnan(humidity) || isnan(temperature)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  // Creating a JSON formatted string to send via MQTT
  String payload = "{\"temperature\": ";
  payload += String(temperature);
  payload += ", \"humidity\": ";
  payload += String(humidity);
  payload += "}";

  // Publish temperature and humidity data to the MQTT broker
  Serial.print("Publishing message: ");
  Serial.println(payload);

  client.publish(mqtt_topic, (char*) payload.c_str());

  delay(5000);  // Publish data every 5 seconds
}