# Welcome to The Bin! 🦝

Now that you've thrown some parts into The Bin, it's time to turn that trash into treasure! 🗑️➡️💎

Wire up your parts and write some code to make them work together. If you need
help with a part, click the "?" above it.

If you want to see examples, check here:
https://hack.club/bin-example

You can get help by chatting with other high schoolers on the Hack Club Slack in
the #electronics channel:
👉 https://hackclub.com/slack 👈

Once you're ready build your design IRL, click the "Share" button and submit
your design:
https://hack.club/bin-submit
    

help.md

#include <Wire.h>
#include <Adafruit_NeoPixel.h>
#include <SSD1306Ascii.h>
#include <SSD1306AsciiWire.h>
#include <LiquidCrystal_I2C.h>
#include "bargraph.h"

// OLED Display configuration
#define OLED_I2C_ADDRESS 0x3C
#define OLED_RST_PIN -1

// LCD configuration
#define LCD_I2C_ADDRESS 0x27
#define LCD_COLUMNS 16
#define LCD_LINES 2

// Fader configuration
#define FADER_PIN A2

// Analog stick configuration
#define ANALOG_STICK_VERTICAL_PIN A0
#define ANALOG_STICK_HORIZONTAL_PIN A1
#define ANALOG_STICK_SEL_PIN 22

// Neopixel configuration
#define NEOPIXEL_PIN 21
#define NEOPIXEL_COUNT 1

// Rotary Encoder configuration
#define ROTARY_ENCODER_CLK_PIN 13
#define ROTARY_ENCODER_DT_PIN 14
#define ROTARY_ENCODER_SW_PIN 15

// Bar graph configuration
#define BAR_GRAPH_DATA_PIN 16
#define BAR_GRAPH_CLOCK_PIN 18
#define BAR_GRAPH_LATCH_PIN 17
#define BAR_GRAPH_LED_PIN_8 19
#define BAR_GRAPH_LED_PIN_9 20

// Create an object for the bar graph
Bargraph bargraph(BAR_GRAPH_DATA_PIN, BAR_GRAPH_CLOCK_PIN, BAR_GRAPH_LATCH_PIN, BAR_GRAPH_LED_PIN_8, BAR_GRAPH_LED_PIN_9);

// Create an object for the LCD
LiquidCrystal_I2C lcd(LCD_I2C_ADDRESS, LCD_COLUMNS, LCD_LINES);

// Create an object for the Neopixel
Adafruit_NeoPixel strip(NEOPIXEL_COUNT, NEOPIXEL_PIN, NEO_GRB + NEO_KHZ800);

// Create an object for the OLED
SSD1306AsciiWire oled;

// Variables to store some persistent data
int faderPosition = 0;
int lastFaderPosition = 0;
int analogStickX = 0;
int lastAnalogStickX = 0;
int analogStickY = 0;
int lastAnalogStickY = 0;
int ledBrightness = 255;

void updateLCD() {
  lcd.clear();
  lcd.print("Volume ");
  lcd.print(map(faderPosition, 0, 1023, 0, 100));
  lcd.println("%");
}

void updateOLED() {
  oled.clear();
  oled.print("Modulation ");
  oled.println(map(analogStickX, 0, 1023, -100, 100));
  oled.print("Pitch ");
  oled.println(map(analogStickY, 0, 1023, -100, 100));
}

void setup() {
  // put your setup code here, to run once:
  Serial1.begin(115200);
  Serial1.println("Hello, Raspberry Pi Pico W!");
  
  // Set up I2C
  Wire.begin();
  Wire.setClock(400000L);

  // Set up the LCD
  lcd.init();
  lcd.backlight();

  strip.begin();
  strip.setPixelColor(0, 255, 255, 0);
  strip.show(); // Initialize LEDs

#if OLED_RST_PIN >= 0
  oled.begin(&Adafruit128x64, OLED_I2C_ADDRESS, OLED_RST_PIN);
#else
  oled.begin(&Adafruit128x64, OLED_I2C_ADDRESS);
#endif
  
  oled.setFont(System5x7);

  // Set up the rotary encoder
  pinMode(ROTARY_ENCODER_DT_PIN, INPUT);
  pinMode(ROTARY_ENCODER_CLK_PIN, INPUT);
  attachInterrupt(ROTARY_ENCODER_CLK_PIN, updateEncoder, FALLING);

  // Initialize the displays
  bargraph.write(0);
  updateLCD();
  updateOLED();
}

void loop() {
  // put your main code here, to run repeatedly:
  delay(1); // this speeds up the simulation

  // Check if the controls have been moved and do things if they have
  faderPosition = analogRead(FADER_PIN);
  if (faderPosition != lastFaderPosition) {
    Serial1.print("vol ");
    Serial1.println(faderPosition);

    updateLCD();

    lastFaderPosition = faderPosition;
  }

  analogStickX = analogRead(ANALOG_STICK_HORIZONTAL_PIN);
  if (analogStickX != lastAnalogStickX) {
    Serial1.print("mod ");
    Serial1.println(analogStickX);

    updateOLED();

    lastAnalogStickX = analogStickX;
  }

  analogStickY = analogRead(ANALOG_STICK_VERTICAL_PIN);
  if (analogStickY != lastAnalogStickY) {
    Serial1.print("pitch ");
    Serial1.println(analogStickY);

    bargraph.write(map(analogStickY, 0, 1023, 0, 10));

    updateOLED();

    lastAnalogStickY = analogStickY;
  }

  strip.setPixelColor(0, map(analogStickX, 0, 1023, 0, ledBrightness), map(analogStickY, 0, 1023, 0, ledBrightness), 0);
  strip.show(); // Initialize LEDs
}

void updateEncoder() {
  // Change LED brightness depending on spin direction
  if (digitalRead(ROTARY_ENCODER_DT_PIN) == HIGH) {
    ledBrightness += 10;
    if (ledBrightness > 255) {
      ledBrightness = 255;
    }
  } else{
    ledBrightness -= 10;
    if (ledBrightness < 0) {
      ledBrightness = 0;
    }
  }
}

sketch.ino

diagram.json

#ifndef BARGRAPH_H
#define BARGRAPH_H

#include <Arduino.h>

class Bargraph {
  private:
    byte dataPin; // DS
    byte clockPin; // SHCP
    byte latchPin; // STCP
    byte ledPin8;
    byte ledPin9;
    int pattern;
    
  public:
    // Setup bar graph and call init()
    Bargraph(byte dataPin, byte clockPin, byte latchPin, byte ledPin8, byte ledPin9);

    // Setup the bargraph
    void init();
    
    // Set a value to the bargraph
    void write(byte value);
};

#endif

bargraph.h

#include "bargraph.h"

Bargraph::Bargraph(byte dataPin, byte clockPin, byte latchPin, byte ledPin8, byte ledPin9) {
  this->clockPin = clockPin;
  this->dataPin = dataPin;
  this->latchPin = latchPin;
  this->ledPin8 = ledPin8;
  this->ledPin9 = ledPin9;
  init();
}

void Bargraph::init() {
  pinMode(dataPin, OUTPUT);
  pinMode(clockPin, OUTPUT);
  pinMode(latchPin, OUTPUT);
  pinMode(ledPin8, OUTPUT);
  pinMode(ledPin9, OUTPUT);
  this->pattern = 0b0000000000;
}

void Bargraph::write(byte value) {
  // Loop through the possible outputs on the shift register, and set the bits depending on whether that output should be on or not
  for (int i = 0; i <= 9; i++) {
    bitWrite(pattern, i, i <= (value - 1));
  }

  // Write the pattern to the shift register
  digitalWrite(latchPin, LOW);
  shiftOut(dataPin, clockPin, MSBFIRST, pattern);
  digitalWrite(latchPin, HIGH);

  // Set the LEDs that are not connected to the shift register
  digitalWrite(ledPin8, bitRead(pattern, 8));
  digitalWrite(ledPin9, bitRead(pattern, 9));
}

bargraph.cpp

# Wokwi Library List
# See https://docs.wokwi.com/guides/libraries

# Automatically added based on includes:
Adafruit NeoPixel
LiquidCrystal I2C

SSD1306Ascii
