#include <WiFi.h>
#include "PubSubClient.h"
#include "ArduinoJson.h"
#include "DHT.h"


const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqttUser = "emqx";
const char* mqttPassword = "public";
const char* mqttServer = "broker.emqx.io";

int port = 1883;
String stMac;
char mac[50];
char clientId[50];
char mqttTopic[50];

WiFiClient espClient;
PubSubClient client(espClient);


const int ledPin = 2;

const int pirPin = 12;
const int dhtPin = 13;
DHT dht(dhtPin,DHT22);

int calibrationTime = 30;

long unsigned int lowIn;

long unsigned int pauseValue = 5000;

boolean lockLow = true;
boolean takeLowTime;
long unsigned int lastSend=millis();

const char* ntpServer = "pool.ntp.org";

unsigned long epochTime; 

void setup() {
  Serial.begin(115200);
  randomSeed(analogRead(0));

  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  wifiConnect();

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  Serial.println(WiFi.macAddress());
  stMac = WiFi.macAddress();
  stMac.replace(":", "_");
  Serial.println(stMac);
  
  client.setServer(mqttServer, port);
  client.setCallback(callback);
  pinMode(ledPin, OUTPUT);
  pinMode(pirPin, INPUT);
  pinMode(dhtPin, INPUT);
  digitalWrite(pirPin, LOW);
  configTime(0, 0, ntpServer);
}

void wifiConnect() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
}

void publishMsg(char* msg)
{
  client.publish(mqttTopic,msg);
}


void mqttReconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    long r = random(1000);
    sprintf(clientId, "clientId-%ld", r);
    sprintf(mqttTopic, "iotProjectTPPKM/sensorTopic");
    if (client.connect(clientId,mqttUser,mqttPassword)) {
      Serial.print(clientId);
      Serial.println(" connected");
      client.subscribe(mqttTopic);      
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}


void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.print(topic);
  Serial.print(". Message: ");
  String stMessage;
  
  for (int i = 0; i < length; i++) {
    Serial.print((char)message[i]);
    stMessage += (char)message[i];
  }
  Serial.println();

  if (String(topic) == String(mqttTopic)) {
    Serial.print("Changing output to ");
    if(stMessage == "on"){
      Serial.println("on");
      digitalWrite(ledPin, HIGH);
    }
    else if(stMessage == "off"){
      Serial.println("off");
      digitalWrite(ledPin, LOW);
    }
  }
}

unsigned long getTime() {
  time_t now;
  struct tm timeinfo;
  if (!getLocalTime(&timeinfo)) {
    return(0);
  }
  time(&now);
  return now;
}

void sendData()
{
  JsonDocument sensorData;

  sensorData["time"]=String(getTime());

  JsonArray data = sensorData["data"].to<JsonArray>();
  
  JsonDocument pirData;
  pirData["value"]=digitalRead(pirPin);
  pirData["sensor"]="pir";

  JsonDocument humidityData;
  humidityData["value"]=dht.readHumidity();
  humidityData["sensor"]="humidity"; 

  JsonDocument temperatureData;
  temperatureData["value"]=dht.readTemperature();
  temperatureData["sensor"]="temperature"; 

  data.add(pirData);
  data.add(humidityData);
  data.add(temperatureData);

  String serialized;

  serializeJson(sensorData,serialized);
  
  int len=serialized.length()+1;
  char buf[len];
  serialized.toCharArray(buf,len);
  publishMsg(buf);
}

void loop() {
  delay(10);
  if (!client.connected()) {
    mqttReconnect();
  }
  client.loop();


  if(millis()-lastSend>pauseValue)
  {
    sendData();
    lastSend=millis();
  }

  if (digitalRead(pirPin) == HIGH) {
 digitalWrite(ledPin, HIGH); 
 if (lockLow) {
 
 lockLow = false;
 Serial.println("---");
 Serial.print("motion detected at "); 
 sendData();
 Serial.print(millis() / 1000);
 Serial.println(" sec");
 delay(50);
 }
 takeLowTime = true;
 }
 
 if (digitalRead(pirPin) == LOW) {
 digitalWrite(ledPin, LOW); 
 
 if (takeLowTime) {
 lowIn = millis();          
 takeLowTime = false;       
 }

 if (!lockLow && millis() - lowIn > pauseValue) {
 lockLow = true;
 Serial.print("motion ended at ");     
 Serial.print((millis() - pauseValue) / 1000);
 Serial.println(" sec");
  
 delay(50);
 }
 }


}