#include <WiFi.h>  // Biblioteca para conexão Wi-Fi do ESP32
#include <PubSubClient.h>  // Biblioteca para usar o protocolo MQTT
#include <DHT.h>  // Biblioteca para comunicação com o sensor de temperatura e umidade DHT

// Neste caso de simulação, usamos os valores abaixo.
const char* ssid = "Wokwi-GUEST";  // Nome da rede Wi-Fi (SSID)
const char* password = "";  // Senha da rede Wi-Fi (vazia para a simulação)

// Neste exemplo de simulação, usamos o broker público Mosquitto.
const char* mqtt_server = "test.mosquitto.org";  // Broker MQTT
char* Temp = "/IoT1/temp";  // Tópico MQTT para publicar temperatura
char* Humid = "/IoT1/humid";  // Tópico MQTT para publicar umidade
const char* ledTopic = "/IoT1/led";  // Tópico para controlar o LED

WiFiClient espClient;  // Objeto para gerenciar a conexão Wi-Fi
PubSubClient client(espClient);  // Cliente MQTT baseado na conexão Wi-Fi

DHT dht(12, DHT22);  // Objeto que representa o sensor DHT22 conectado ao pino GPIO 4

const int ledPin = 2;  // Definir o pino GPIO onde o LED está conectado

void callback(char* topic, byte* message, unsigned int length) {
 
  String messageTemp;

  if(length >= 1){
  
    // Converte o conteúdo da mensagem em uma string
    for (int i = 0; i < length; i++) {
      messageTemp += (char)message[i];
    }

    Serial.print("Mensagem recebida no tópico: ");
    Serial.println(topic);
    Serial.print(". Mensagem: ");
    Serial.println(messageTemp);
    delay(2000);
  }

  // Verifica se a mensagem recebida é para o tópico do LED
  if (String(topic) == ledTopic) {
    if (messageTemp == "liga") {
      digitalWrite(ledPin, HIGH);  // Liga o LED
      Serial.println("LED Ligado");
    } else if (messageTemp == "desliga") {
      digitalWrite(ledPin, LOW);  // Desliga o LED
      Serial.println("LED Desligado");
    }
    delay(2000);
  }
}

// Função para conectar o ESP32 ao Wi-Fi
void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);  // Exibe o nome da rede que está tentando conectar
  WiFi.begin(ssid, password);  // Inicia a conexão Wi-Fi
  while (WiFi.status() != WL_CONNECTED) {  // Enquanto não estiver conectado
    delay(500);
    Serial.print(".");  // Imprime pontos a cada meio segundo enquanto tenta conectar
  }
  Serial.println("");
  Serial.println("WiFi connected");  // Conexão Wi-Fi estabelecida
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());  // Exibe o endereço IP local do ESP32
}

// Função para reconectar ao broker MQTT se a conexão for perdida
void reconnect() {
  while (!client.connected()) {  // Enquanto o cliente MQTT não estiver conectado
    Serial.print("Attempting MQTT connection...");
    if (client.connect("ESPClient")) {  // Tenta conectar ao broker MQTT
      Serial.println("connected");  // Conexão bem-sucedida
      client.subscribe(Temp);  // Inscreve-se no tópico de temperatura
      client.subscribe(Humid);  // Inscreve-se no tópico de umidade
      client.subscribe(ledTopic);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());  // Exibe o estado de erro, caso falhe
      Serial.println(" try again in 5 seconds");  // Tenta novamente em 5 segundos
      delay(5000);  // Aguarda 5 segundos antes de tentar reconectar
    }
  }
}

void setup() {
  Serial.begin(115200);  // Inicializa a comunicação serial para depuração com velocidade de 115200 baud
  setup_wifi();  // Chama a função para conectar ao Wi-Fi
  client.setServer(mqtt_server, 1883);  // Configura o servidor MQTT e a porta 1880 (porta padrão do MQTT)
  client.setCallback(callback);  // Registra a função callback para processar mensagens recebidas

  dht.begin();  // Inicializa o sensor DHT22
  pinMode(ledPin, OUTPUT);
  digitalWrite(ledPin, LOW);  // Desliga o LED
  delay(2000);  // Aguarda 2 segundos para o sensor DHT estabilizar
}

// Função principal do loop
void loop() {
  if (!client.connected()) {  // Verifica se o cliente MQTT está conectado
    reconnect();  // Se não estiver, tenta reconectar
  }
  client.loop();  // Mantém o cliente MQTT rodando e processando mensagens
  delay(100);  // Adiciona um pequeno delay para evitar sobrecarga

  // Leitura dos dados do sensor DHT22
  float temp = dht.readTemperature();  // Lê a temperatura
  float humidity = dht.readHumidity();  // Lê a umidade

  // Exibe a temperatura e umidade no console serial
  Serial.print("Temp : ");
  Serial.print(temp);
  Serial.println(" C ");
  Serial.print("Humidity : ");
  Serial.print(humidity);
  Serial.println(" % ");

  // Converte os valores de temperatura e umidade para string para enviar via MQTT
  String messaget = String(temp);  // Converte a temperatura para string
  String messageh = String(humidity);  // Converte a umidade para string

  // Publica os valores nos tópicos MQTT respectivos
  client.publish("/IoT1/temp", messaget.c_str());  // Publica a temperatura
  client.publish("/IoT1/humid", messageh.c_str());  // Publica a umidade

  delay(200);  // Espera 200 milissegundos antes de repetir o loop
}