#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

// WiFi credentials
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// MQTT broker details
const char* mqtt_server = "test.mosquitto.org";
const int mqtt_port = 1883;
const char* pub_topic = "tulip/dht";

// DHT sensor settings
#define DHTPIN 12          // GPIO pin where the DHT sensor is connected
#define DHTTYPE DHT22     // DHT11 or DHT22, define accordingly
DHT dht(DHTPIN, DHTTYPE);

// Create WiFi and MQTT clients
WiFiClient espClient;
PubSubClient client(espClient);

// Function to connect to WiFi
void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
}

// Function to connect to the MQTT broker
void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Try to connect, no username/password needed for Mosquitto
    if (client.connect("tulip_wokwi_test")) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(100);
    }
  }
}

void setup() {
  Serial.begin(115200);
  setup_wifi();
  
  client.setServer(mqtt_server, mqtt_port);
  dht.begin();  // Initialize DHT sensor
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  static unsigned long lastMsg = 0;
  unsigned long now = millis();

  if (now - lastMsg > 2000) {  // Read and publish every 2 seconds
    lastMsg = now;

    // Reading temperature and humidity
    float h = dht.readHumidity();
    float t = dht.readTemperature(); // Celsius

    // Check if any reads failed and exit early (to try again).
    if (isnan(h) || isnan(t)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
    }

    // Publish temperature and humidity data
    String payload = "{\"temperature\":" + String(t) + ",\"humidity\":" + String(h) + "}";
    Serial.print("Publishing message: ");
    Serial.println(payload);
    client.publish(pub_topic, payload.c_str());
  }
}