#include <DHTesp.h>
#include <PubSubClient.h>
#include <WiFi.h>

#define PIN_LED 15 // GPIO to LED
#define PIN_DHT 2 // GPIO to DHT sensor

/* Configuration of Topic to MQTT */
#define TOPIC_SUBSCRIBE_LED       "topic_on_off_led"
#define TOPIC_PUBLISH_TEMPERATURE "topic_sensor_temperature"
#define TOPIC_PUBLISH_HUMIDITY    "topic_sensor_humidity"

#define PUBLISH_DELAY 2000   // Delay time for publish data to MQTT Broker

#define ID_MQTT "esp32_mqtt" // Device ID for connect to MQTT Broker


DHTesp dht;

const char *SSID = "Wokwi-GUEST"; // SSID / nome da rede WI-FI que deseja se conectar
const char *PASSWORD = "";        // Senha da rede WI-FI que deseja se conectar

// URL for MQTT broker
const char *BROKER_MQTT = "broker.hivemq.com";
int BROKER_PORT = 1883; // Port of Broker MQTT

unsigned long publishUpdate;

static char strTemperature[10] = {0};
static char strHumidity[10] = {0};

// Variable for Wifi Client Object
WiFiClient espClient;         
PubSubClient MQTT(espClient);

/* Prototypes */
float getTemperature(void);
float getHumidity(void);

void initWiFi(void);
void initMQTT(void);
void callbackMQTT(char *topic, byte *payload, unsigned int length);
void reconnectMQTT(void);
void reconnectWiFi(void);
void checkWiFIAndMQTT(void);

/* Function for get Temperature  */
float getTemperature(void)
{
  TempAndHumidity data = dht.getTempAndHumidity();

  if (!(isnan(data.temperature)))
    return data.temperature;
  else
    return -99.99;
}

/* Function for get Humidity  */
float getHumidity(void)
{
  TempAndHumidity data = dht.getTempAndHumidity();

  if (!(isnan(data.humidity)))
    return data.humidity;
  else
    return -99.99;
}

/* Initial WI-FI  */
void initWiFi(void)
{
  delay(10);
  Serial.println("------Connect to WI-FI------");
  Serial.print("Connecting to : ");
  Serial.println(SSID);

  reconnectWiFi();
}

/* Initial MQTT  */
void initMQTT(void)
{
  MQTT.setServer(BROKER_MQTT, BROKER_PORT); 
  MQTT.setCallback(callbackMQTT);
}

/* Function Callback: Receive Message from another MQTT Client publish message pass through the MQTT Broker */
void callbackMQTT(char *topic, byte *payload, unsigned int length)
{
  String msg;

  // Obtem a string do payload recebido
  for (int i = 0; i < length; i++) {
    char c = (char)payload[i];
    msg += c;
  }

  Serial.printf("Receive string via MQTT: %s on topico: %s\n", msg, topic);

  /* Toma ação dependendo da string recebida */
  if (msg.equals("1")) {
    digitalWrite(PIN_LED, HIGH);
    Serial.println("LED status ON");
  }

  if (msg.equals("0")) {
    digitalWrite(PIN_LED, LOW);
    Serial.println("LED status OFF");
  }
}

/* FUnction reconnect MQTT Broker */
void reconnectMQTT(void)
{
  while (!MQTT.connected()) {
    Serial.print("* Connecting MQTT Broker: ");
    Serial.println(BROKER_MQTT);
    if (MQTT.connect(ID_MQTT)) {
      Serial.println("Connecting the MQTT Broker success!");
      MQTT.subscribe(TOPIC_SUBSCRIBE_LED);
    } else {
      Serial.println("Fail to connect then reconnect MQTT Broker again in 2 seconds.");
      delay(2000);
    }
  }
}

/* Function checking connected to WiFI and MQTT Broker */
void checkWiFIAndMQTT(void)
{
  if (!MQTT.connected())
    reconnectMQTT(); 
  reconnectWiFi(); 
}

void reconnectWiFi(void)
{
  if (WiFi.status() == WL_CONNECTED)
    return;

  WiFi.begin(SSID, PASSWORD); 

  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
    Serial.print(".");
  }

  Serial.println();
  Serial.print("Connected WiFi success. ");
  Serial.print(SSID);
  Serial.println("IP Address: ");
  Serial.println(WiFi.localIP());
}

void setup()
{
  Serial.begin(115200);

  pinMode(PIN_LED, OUTPUT);
  digitalWrite(PIN_LED, LOW);

  // Setup DHT sensor
  dht.setup(PIN_DHT, DHTesp::DHT22);

  initWiFi();
  initMQTT();
}

void loop()
{
  /* Repeat every 2 seconds (PUBLISH_DALAY)*/

  if ((millis() - publishUpdate) >= PUBLISH_DELAY) {
    publishUpdate = millis();
    // Verifica o funcionamento das conexões WiFi e ao broker MQTT
    checkWiFIAndMQTT();

    // Change format of the Data as String for send it via MQTT protocol
    sprintf(strTemperature, "%.2fC", getTemperature());
    sprintf(strHumidity, "%.2f", getHumidity());

    // Send data string to MQTT Broker
    MQTT.publish(TOPIC_PUBLISH_TEMPERATURE, strTemperature);
    MQTT.publish(TOPIC_PUBLISH_HUMIDITY, strHumidity);
    Serial.print("Publish suhu: ");
    Serial.println(strTemperature);

    // Keep-alive for connected MQTT broker
    MQTT.loop();
  }
}