#include <WiFi.h>
#include <PubSubClient.h>
#include "DHTesp.h"

// Credenciais de rede Wi-Fi e servidor MQTT
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "test.mosquitto.org"; // Servidor MQTT

// Definições do pino para o sensor DHT e LEDs de status
const int DHT_PIN = 23; 
DHTesp dhtSensor;

WiFiClient WOKWI_client;
PubSubClient client(WOKWI_client);

// Variáveis para receber mensagens
String my_payload;
String my_topic;

// Funções de configuração da conexão Wi-Fi
void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

// Função para reconectar ao servidor MQTT
void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect("WOKWI_client")) {
      Serial.println("connected");
      client.subscribe("TOPIC_BIA"); // Inscrever-se no tópico para receber mensagens
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

// Função callback para receber mensagens MQTT
void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");

  String conc_payload;
  for (int i = 0; i < length; i++) {
    conc_payload += ((char)payload[i]);
  }

  my_topic = topic;
  my_payload = conc_payload;
}

// Funções para indicar status de conexão via LEDs
void Conectado_Wifi() {
  if (WiFi.status() == WL_CONNECTED)
    digitalWrite(2, HIGH);
  else
    digitalWrite(2, LOW);
}

void Conectado_Mosquito() {
  if (client.connected())
    digitalWrite(15, HIGH);
  else
    digitalWrite(15, LOW);
}

// Função para acionar saída com base no payload MQTT recebido
void recebe_dados() {
  if (my_payload == "A")
    digitalWrite(19, HIGH);
  if(my_payload == "a")
    digitalWrite(19, LOW);
}

// Função para enviar temperatura e umidade via MQTT
void envio_temp() {
  TempAndHumidity data = dhtSensor.getTempAndHumidity();
  client.publish("TOPICO_TEMP_B", String(data.temperature).c_str());
  client.publish("TOPICO_HUMI_B", String(data.humidity).c_str());
  
  Serial.println("Temp: " + String(data.temperature, 2) + "°C");
  Serial.println("Humidity: " + String(data.humidity, 1) + "%");
  Serial.println("---");
  delay(2000); // Aguarda nova leitura
}

// Configuração inicial
void setup() {
  pinMode(2, OUTPUT);  
  pinMode(15, OUTPUT);  
  pinMode(19, OUTPUT);  
  Serial.begin(115200);

  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22); // Inicializa o sensor DHT22
}

// Loop principal
void loop() {
  reconnect();
  Conectado_Wifi();
  Conectado_Mosquito();
  recebe_dados();
  envio_temp();
  client.loop(); // Mantém a conexão MQTT ativa e processa as mensagens
}